Přeskočit navigaci | Přeskočit na novinky
     

Jste zde: Úvodní stránka » excel » funkce-textove » LET-prakticky
Microsoft Excel logo

LET prakticky - Excel

Videokurzy Excel

Ve spolupráci se SEDUO jsem vytvořil několik videokurzů:

Jak prakticky na funkci LET.

Základ o funkci jsme popsal v článku: LET - základní použití.

Obsah článku

V tomto článku se podíváme na praktické použití a zpřehlednění funkcí, které v Excel používáte.


Rychlé zopakovaní syntaxe

Rychle zopakovaní funkce LET:

=LET(název1;hodnota_názvu1;výpočet_nebo_název2;[hodnota_názvu2];...)

Argumenty:

  • název1 - jak chcete proměnou pojmenovat
  • hodnota_názvu1 - hodnota této proměnné (může jít i o matici)
  • výpočet_nebo_název2 - výsledek (výpočet) - jak ho vypočíst, nebo další název proměnné2
  • hodnota_názvu2 - hodnota názvu 2 pokud v předchozím je název promění

Známka dle bodů

Na základě získaných bodů, které mohou být od 0 až 100, potřebujete získat známku:

  • A - 90 (včetně) a více
  • B - 80 (včetně) a více
  • C - 70 (včetně) a více
  • D - 60 (včetně) a více
  • E - 50 (včetně) a více
  • F - 0 (včetně) a více

Lze využít funkci KDYŽ a vnořovat:

=KDYŽ(B13>=90;"A";KDYŽ(B13>=80;"B";KDYŽ(B13>=70;"C";KDYŽ(B13>=60;"D";KDYŽ(B13>=50;"E";"F")))))

Případně funkci IFS

=IFS(B16>=90;"A";B16>=80;"B";B16>=70;"C";B16>=60;"C";B16>=50;"D";B16>=0;"E")

Bohužel, se několikrát odkazujete na stejnou buňku, ale co když se změní adresa buňky, tak nesmíte zapomenout ji 5x změnit ve funkci. Pokud využijete funkci LET, hodnotu buňky pojmenujete, jednou se odkážete a následně ve vzorci využijete použitý název. Pokud dojde ke změně adresy buňky, jen změníte jednu hodnotu.

Pokud použijete funkci LET s KDYŽ

=LET(Body;B19;KDYŽ(Body>=90;"A";KDYŽ(Body>=80;"B";KDYŽ(Body>=70;"C";KDYŽ(Body>=60;"D";KDYŽ(Body>=50;"E";"F"))))))

Pokud použijete funkci LET s IFS

=LET(Bd;B23;IFS(Bd>=90;"A";Bd>=80;"B";Bd>=70;"C";Bd>=60;"C";Bd>=50;"D";Bd>=0;"E")) Excel - LET

Text na základě známky

Na základě známky přiřadit text:

  • 1 - Výborně
  • 2 - Chvalitebně
  • 3 - Dobře
  • 4 - Dostatečně
  • 5 - Nedostatečně

Lze využít funkci KDYŽ a řetězit:

=KDYŽ(B13=1;"Výborně";KDYŽ(B13=2;"Chvalitebně";KDYŽ(B13=3;"Dobře";KDYŽ(B13=4;"Dostatečně";"Nedostatečně"))))

Využít funkce IFS

=IFS(B17=1;"Výborně";B17=2;"Chvalitebně";B17=3;"Dobře";B17=4;"Dostatečně";B17=5;"Nedostatečně")

Nebo funkce SWITCH, zde se jen odkážete na jednu hodnotu, proto možná ve spojení s LET nedává smysl:

=SWITCH(B20;1;"Výborně";2;"Chvalitebně";3;"Dobře";4;"Dostatečně";5;"Nedostatečně")

Funkce KDYŽ ve spojení s LET

=LET(B;B23;KDYŽ(B=1;"Výborně";KDYŽ(B=2;"Chvalitebně";KDYŽ(B=3;"Dobře";KDYŽ(B=4;"Dostatečně";"Nedostatečně")))))

Funkce IFS ve spojení s LET

=LET(Bd;B27;IFS(Bd=1;"Výborně";Bd=2;"Chvalitebně";Bd=3;"Dobře";Bd=4;"Dostatečně";Bd=5;"Nedostatečně"))

Funkce SWITCH ve spojení s LET, zde jde o změnu jedné proměnné tak jen pro ilustraci:

=LET(B;B30;SWITCH(B;1;"Výborně";2;"Chvalitebně";3;"Dobře";4;"Dostatečně";5;"Nedostatečně")) Excel LEt - text dle známky

Číselné řady - opakování dle počtu hodnot

Pro další použití a ukázku práce s novými funkcemi, se podíváme jak vytvořit dynamickou řadu, která bude mít počet opakování dle počtu hodnot, navíc bude chtít mít hodnoty různě seřazeny, například pro dvě hodnoty budou dvě opakování z těchto dvou hodnot:

  • 1
  • 2
  • 1
  • 2

Nebo

  • 1
  • 1
  • 2
  • 2

Pro tři hodnoty 1,2,3 tři opakování atd.

Excel LET

Pokud chcete načíslovat 1 až požadované číslo a následně zopakovat 1 až požadované číslo atd.:

=KDYŽ(MOD(SEQUENCE(B4*B4);B4)=0;B4;MOD(SEQUENCE(B4*B4);B4))

Ve funkci se několikrát odkazujete na stejnou hodnotu. Proto když přepíšete s využitím LET funkce se zpřehlední:

=LET(p;B4; KDYŽ(MOD(SEQUENCE(p*p);p)=0;p;MOD(SEQUENCE(p*p);p)))

Budete-li chtít zopakovat stejné číslo s požadovaným počtem opakování a následně následující číslo s požadovaným počtem opakování atd.:

=ROUNDUP(SEQUENCE(B4*B4)/B4;0)

A z důvodu přehlednosti opět využijeme funkci LET

=LET(p;B4;ROUNDUP(SEQUENCE(p*p)/p;0)) Excel

Číselné řady s požadovaným počtem opakováním

První číselnou řadu máme za sebou, ale co když budu potřebovat, aby počet opakování byl jiný než počet hodnot v číselné řadě, například čísla 1 a 2 ale zopakovat 3 krát?

  • 1
  • 2
  • 1
  • 2
  • 1
  • 2

Nebo

  • 1
  • 1
  • 1
  • 2
  • 2
  • 2
Excel - ciselne rady 2

Můžeme vyjít z předchozí kapitoly a mírně upravit vzorečky

=KDYŽ(MOD(SEQUENCE(B4*B5);B5)=0;B5;MOD(SEQUENCE(B4*B5);B5))

Případně využít funkci LET

=LET(opak;B4;hodn;B5; KDYŽ(MOD(SEQUENCE(opak*hodn); hodn)=0;hodn;MOD(SEQUENCE(opak*hodn);hodn)))

Nebo chcete-li stejná čísla za sebou a mít požadovaný počet opakování

=ROUNDUP(SEQUENCE(B4*B5)/B4;0)

s využitím funkce LET

=LET(opak;B4;hodnot;B5;ROUNDUP(SEQUENCE(opak*hodnot)/opak;0)) Excel - ciselne rady 2

Závěrem

Narazili jste na nějaký problém/ nejasnost? Máte tip na doplnění, můžete to zmínit v komentářích.

Článek byl aktualizován: 30.03.2022 12:47

Odměna

Ušetřil vám tento web čas, peníze? Pomohl vyřešit problém? Jste ochotni poskytnout symbolickou odměnu na další rozvoj? Vybrte si formu odměny, která vám vyhovuje.


Pavel Lasák - autor webu

Pavel Lasák

Microsoft Office (Word, Excel, Google tabulky, PowerPoint) se věnuji od roku 2000 (od 2004 na této doméně) - V roce 2017 jsem od Microsoft získal prestižní ocenění MVP (zatím jsem jediný z ČR v kategorií Excel). Své vědomosti a zkušenosti dávám k dispozici i on-line ve videích pro SEDUO. Ve firmách školím a konzultuji, učím na MUNI. Tento web již tvořím přes 15 let. Zdarma je zde přes 1.000 návodu, tipů a triků, včetně přes 250 různých šablon, sešitů.

   Pavel Lasák LinkedIn Profil    Pavel Lasák Google+ Profil    Pavel Lasák facebook Profil    Pavel Lasák twitter Profil


Komentáře zatím nejsou

Můžete být prvními co zanechají smysluplný komentář.






Excel


Sdílejte

Pomohl Vám návod?
Sdílejte na Facebooku, G+
LinkedIn...

Nové články


Reklama


TOPlist Licence Creative Commons webarchiv rss XML

Stránky o MS Office (Excel) produktu společnosti Microsoft. Neslouží jako technická podpora.
| Email na autora: pavel.lasak@gmail.com | Copyright © : Pavel Lasák 2004 - 2021 |