Přeskočit navigaci | Přeskočit na novinky

Nový videokurz na Seduo: Excel pro začátečníky

     

Jste zde: Úvodní stránka » excel » funkce » kdyz-funkce-logicka-excel

KDYŽ / IF - funkce logická - Excel


Praktické použití funkce KDYŽ / IF, příklady, návody, soubory ke stažení s praktickými ukázkami pro Microsoft Excel. Vše co chcete o KDYŽ vědět a bojíte se zeptat.

29.1.2016: Využití KDYŽ v maticích a KDYŽ a kontrola textů.

Cílem článku o funkci KDYŽ

Na praktických příkladech ukázat použití jedné z nejdůležitějších a nejpoužívanějších funkcí KDYŽ / IF v MS Excelu.

Veškeré prezentované příklady jsou ke stažení zdarma.

V tomto článku se naučíte:

KDYŽ - IF ... syntaxe

Vrátí zadanou hodnotu, pokud je zadaná podmínka vyhodnocena jako PRAVDA, a jinou hodnotu, pokud je zadaná podmínka vyhodnocena jako NEPRAVDA.

Syntaxe v češtině

=KDYŽ(Podmínka; Ano; Ne)

Syntaxe v angličtině

=IF(Podmínka; Ano; Ne)

Poznámka: funguje i v google dokumentech.

Popis argumentu

  • Podmínka - libovolná hodnota (výraz), který může nabývat hodnotu PRAVDA nebo NEPRAVDA
  • Ano - je vrácená zadaná hodnota, je-li hodnota argumentu podmínka PRAVDA.
  • Ne - je vrácená hodnota, je-li hodnota argumentu podmínka NEPRAVDA.

Poznámka: Při použití ve VBA nebo při hledání v anglických textech je tato funkce pod názvem IF - tj. pokud budete hledat u strejdy googla ;-) Navíc v anglické verzi Excelu je oddělovačem čárka ne středník ajko v české.

IF(Podmínka, Ano, Ne)

Parametr - Podmínka - může být:

  • = je rovno
  • <> není rovno
  • > je větší než
  • < je menší než
  • >= je větší nebo rovno
  • <= je menší nebo rovno

Další logické funkce jsem sepsal v článku: Logické funkce - MS Excel - přehled funkcí.

Teorií máte za sebou a jdeme na praktické příklady.

Zpět na seznam kapitol o funkci KDYŽ

Ukázka jak funkce KDYŽ funguje

V gif ukázka jak funguje, mění je jednotlivé podmínky a tím pádem i daný vzorec.

KDYŽ - Microsoft Excel - logická funkce ukázka práce

KDYŽ jednoduchý příklad (jedna podmínka).

Začneme jednoduchým úkolem. Pokud hodnota v požadované buňce A9 je jedna 1 (zadána číslem) potřebujete vypsat: jednička.

Řešení:

=KDYŽ(A9=1;"jednička";"jiné číslo")

Je funkce pochopitelná tak pokračujme.

Zpět na seznam kapitol o funkci KDYŽ

KDYŽ - obrácena logika - jedna podmínka

Pokračujeme jednoduchým úkolem. Kontrolujeme zadané číslo, které nesmí být jedna. Pokud hodnota v požadované buňce A21 je jedna 1 (zadána číslem) potřebujete vypsat: Přepiš na jiné číslo!. Pokud je různá od jedné vypíšete Správně

Řešení:

=KDYŽ(A21<>1;"Správně";"Přepiš na jiné číslo!")

Logiku můžete obrátit a i toto je správné řešení:

=KDYŽ(A21=1;"Přepiš na jiné číslo!";"Správně.")

Obě řešení jsou správná. Zaleží na Vás co se Vám více libí a jak plánujete funkci KDYŽ rozšiřovat (jelikož podmínek může být více). Význam toho pochopíte dále na dalších příkladech.

Zpět na seznam kapitol o funkci KDYŽ

Číselné a textové hodnoty

Rozdíl mezi použitím textových a číselných hodnot ve funkci KDYŽ.

Textové

Při kontrole textových hodnot je potřeba zadávat kontrolovanou hodnotu do uvozovek.

=KDYŽ(A1="B";PRAVDA;NEPRAVDA) =KDYŽ(A1="B";"ANO";"NE") Chybné zadání =KDYŽ(E4=B;PRAVDA;NEPRAVDA) skončí informaci o chybě #NÁZEV?.

Číselné

Číselné hodnoty se zadávají bez uvozovek

=KDYŽ(B1=1;PRAVDA;NEPRAVDA)

Chybné zadání =KDYŽ(B26="1";PRAVDA;NEPRAVDA), pokud je v buňce číslo 1, výsledkem bude NEPRAVDA (ač v buňce je číslo 1)! Dokonce i když bude formát buňky nastavený jako text!

Správně bude vyhodnoceno, jen pokud bude zadáno čísl s apostrofem ', tj. '1.

KDYŽ - použití dvou podmínek - jak vnořovat funkce

Do jedné buňky A26 se má zadat jednička 1 a do buňky A27 zadejte slovo test. Pokud je zadána jen jednička obdržíte info Zadána jen jednička., pokud jen slovo test zadáno jen slovo test, pokud jednička i slovo test Zadána jednička a slovo test. pokud nic Nezadáno nic co je požadováno..

Řešení:

=KDYŽ(A26=1;KDYŽ(A27="test";"Zadána jednička a slovo test.";"Zadána jen jednička.");KDYŽ(A27="test";"zadáno jen slovo test";"Nezadáno nic co je požadováno."))

Řešení další - lze využít i dalších logických funkcí jako A a NEBO což ukáži na dalších příkladech.

Poznámka: Funkce můžete vnořovat více. Od MS Excel 2007 (do verze 2003 je vnoření pouze 7) vnoření může být až 64! Nejvíce jsem použil 10 vnoření, ale třeba někdy v budoucnu...

KDYŽ - ještě více podmínek

Potřebujete k číslenému rozmezí, které bude zadáno v buňce A34 přiřadit písmeno (například školní výsledky testů). Požadované přiřazení je:

  • A větší než 89
  • B 80 - 89
  • C 70 - 79
  • D 60 - 69
  • E menší než 60

Řešení:

=KDYŽ(A34>89;"A";KDYŽ(A34>79;"B";KDYŽ(A34>69;"C";KDYŽ(A34>59;"D";"E"))))

Řešení 2

Pokud buňku do které zadáváte hodnotu pojmenujete průměr

=KDYŽ(průměr>89;"A";KDYŽ(průměr>79;"B";KDYŽ(průměr>69;"C";KDYŽ(průměr>59;"D";"E"))))

Poznámka: Tento úkol je možné řešit i využitím jiné funkce, například pomocí SVYHLEDAT.

Další možnost (1) - SELECT CASE

Ve VBA (Visula Basic pro EXcel) je k dispozici syntaxe CASE SELECT. Podrobněji jsem sepsal samsotatný článek Select Case - Excel VBA, kde jsou k dispozici nejen teoretické informace, ale i praktické příklady ke stažení zdarma.

Další možnost (2) - SVYHLEDAT

Další možnost řešení je využít funkci SVYLHEDAT. Jak řešit pomocí funkce SVYHLEDAT jsem popsal v samostatném článku Jak na funkci SVYHLEDAT prakticky

Absolutní relativní odkazy ve funkci KDYŽ

Při kopírování funkcí v tabulkách. Lze využít absolutních a relativních odkazů. Článek o Relativních a absolutních odkazech .

MS Excel 2010 - KDYŽ

Zpět na seznam kapitol o funkci KDYŽ

Kombinace KDYŽ s jinými funkcemi

Úkol: Zkontrolujte hodnoty v buňkách A72, A73, A74 obsahují hodnoty 1, 2, 3, pokud souhlasí informujte vše OK pokud je min jedna není informujte něco nesplněno pokud nesouhlasí ani jedna Vše nesprávně.

Možné řešení:

=KDYŽ(A(A72=1;A73=2;A74=3);"Vše OK";KDYŽ(NEBO(A72=1;A73=2;A74=3);"Něco nesplněno.";"Vše nesprávně."))

Poznámka: Další použité funkce A a NEBO. Popis těchto funkcí v článku: Logické funkce - MS Excel - přehled funkcí.

Zpět na seznam kapitol o funkci KDYŽ

Chyby ve funkci KDYŽ

Manželka chce po svém muži (programátor) ať zajde nakoupit:

  • Ona: Kup dva rohlíky a když budou mít vajíčka vezmi jich deset.
  • On v obchodě: Máte vajíčka?
  • Prodavačka: Ano.
  • On v obchodě: Tak mi dejte deset rohlíků.

Chyby v logice KDYŽ

Úkol: Zkontrolujte hodnotu v buňce A64 a pokud je menší než 100 informujte menší než 100, pokud je menší než 10 tak informujte menší než 10.

Špatné řešení:

=KDYŽ(A64<100;"menší než 100";KDYŽ(A64<10;"menší než 10";"100 a větší"))

Správné řešení:

=KDYŽ(A64<10;"menší než 10";KDYŽ(A64<100;"menší než 100";"100 a větší"))

Poznámka: pro složitější úlohy doporučuji vyzkoušet všechny varianty, zda Vámi vymyšlená logika funguje správně.

Chyby v zaokrouhlování u funkce KDYŽ

=111,13-111,12 není 0,01 ač to tak na první pohled vypadá ...

Excel pracuje s 15-ti místnou přesnosti a ve dvojkové soustavě. Čímž se může stát, že i vcelku jednoduchý výpočet nebude přesný. Při pokusu o výpočet rozdílů čísel =111,13-111,12 Excel zobrazí správný výsledek 0,01 ve skutečnsoti, ale jde o výsledek 0,0099999999999999091. Což není 0,01!

Ošetřování chyb v buňkách

Funkci když můžete svých spůsobem použít k ošetření chyb.

Potřebujete-li, aby byl v buňce správný výpočet, ale v případě chyby v buňce bude 0.

=KDYŽ(JE.CHYBA(A1);"Je chyba";"Není chyba")

Takže zápis je:

=KDYŽ(JE.CHYBA(A1);0;A1)

Podobně můžete kontrolovat zda je v buňce text:

=KDYŽ(JE.TEXT(A1);"Je Text";"Není text")

K dispozici máte tyto informační funkce:

  • ISEVEN - ISEVEN - PRAVDA pro sudé číslo.
  • ISODD - ISODD - PRAVDA pro liché číslo
  • JE.ČÍSLO - ISNUMBER - Jde o číslo?
  • JE.CHYBA - ISERR - Jde o chybu?
  • JE.CHYBHODN - ISERROR - Jde o chybovou hodnotu?
  • JE.LOGHODN - ISLOGICAL - Jde o logickou hodnotu?
  • JE.NEDEF - ISNA -
  • JE.NETEXT - ISNONTEXT - Jde o netext?
  • JE.ODKAZ - ISREF - Jde o odkaz?
  • JE.PRÁZDNÉ - ISBLANK - Jde o prázdnou?
  • JE.TEXT - ISTEXT - Jde o text?

Více o funkcích informace v samostatném článku: Jak na funkce informace v Microsoft Excelu.

KDYŽ s časem

V komentářích se objevil dotaz na funkce s časem, proto byla doplněna i tato kapitola

Úkol: běh 1000m za čas od 5:15 do 4:50 jsou 4 body, za čas 4:50 do 4:30 je 6 bodů za čas od 4:30 do 4:10 je 8 bodů...

Řešení:

JElikož nebylo zdřejme, kolik bodu dostane čas v mezních bodech 4:50 a 4:30 zvolil jsem si určení sám. Tj. 4:50 dostane 8 a 4:49999 již 6, atd.

=KDYŽ(C12>=$C$5;4;KDYŽ(C12>=$C$6;6;8))

nebo lze využít funkce ČASHODN, jak zodpověděl již Jojo v koemntářích.

=KDYŽ(C12>=ČASHODN("4:50");8;KDYŽ(C12>=ČASHODN("4:30");6;4)) Excel funkce KDYŽ s časem.

Ke stažení

Soubor s ukázkami KDYŽ s časem soubor ve formátu *.xlsx ke stažení zdarma.

Zpět na seznam kapitol o funkci KDYŽ

KDYŽ pro datum

Podobně jako s časem lze pracovat i s datumem. Například máme zjistit zda byla faktura zaplacena včas, nebo pozdě a podle toho doplnit. Sleva (pokud zákazník paltí včas), nebo pokuta (pokud neplatí včas).

=KDYŽ(B9>=C9;"sleva";"pokuta") Excel funkce KDYŽ s datumem.

Ke stažení

Soubor s ukázkami KDYŽ s časem soubor ve formátu *.xlsx ke stažení zdarma.

Zpět na seznam kapitol o funkci KDYŽ

Hledání věkové hranice

Úkol

Podle právního řádu České republiky existuje několik věkových hranic, po jejichž dovršení občan získává způsobilost k některým právním úkonům. Síť. 15 let – způsobilost k trestní odpovědnosti 18 let – volební právo 21 let – právo být volen poslancem PS ČR 40 let – právo být volen senátorem nebo prezidentem Určete dle vašeho data narození (použijte pro hodnocení pouze rok), zda jste výše uvedenou způsobilost již získali či v tomto roce získáte.

Popis řešení

Využijeme funkce KDYŽ a CONCATENATE.

Excel kombinace funkcí.

Ke stažení

Soubor Kombinace funkcí Microsoft Excel soubor ve formátu *.xls ke stažení zdarma.

Zpět na seznam kapitol o funkci KDYŽ

KDYŽ a MIN (MAX, ...)

Jak zkombinovat funkce MIN (MAX, ...) a KDYŽ. Aneb jak najít mininální hodnotu v tabulce pro řádky které vyhovují zadané podmínce.

=MIN(KDYŽ(B5:B14=C18;C5:C14))

Funkce se zadává jako maticová. Podrobněji v článku Jak na matice v Excelu - úvod.

Excel kombinace funkcí MIN a KDYŽ

Další funkce

Na podobném principu lze použít i funkce:

  • MAX
  • PRŮMĚR
  • ...

Ke stažení

Soubor Kombinace funkcí MIN a KDYŽ v Excel soubor ve formátu *.xlsx ke stažení zdarma.

Poznámka: Doplněno na základě dotazů v komentáři.

KDYŽ a HODNOTA.NA.TEXT

Pokud používate formátování datumu, bude mít sešit problémy pokud jej otevřete v anlickém Excelu. Microsoft rád trápí uživatele a v české verzi Excelu se používá pro označení roku písmeno r v anglické y. Proto lze využít funkci KDYŽ a HODNOTA.NA.TEXT.

=KDYŽ(HODNOTA.NA.TEXT(B8;"rr")="rr";HODNOTA.NA.TEXT(B8;"yyyy");HODNOTA.NA.TEXT(B8;"rrrr"))

Předpokládám že v B8 je formát rr a ve vámi určené buňce potřebujete rrrr.

Praktické využití

Například v roční multijazykovém kalendáři, nebo v dashboardech, které musi reflektovat různé jazykové verze.

KDYŽ a NEDEF ...

Praktické využití funkce NEDEF() (v angličtině NA() ) například v grafech, kdy je potřeba jistá data nezobrazit, případně zvýraznit. Místo hodnoty se v buňce zobrazí chybová hodnota #NENÍ_K_DISPOZICI, které se v grafech nezobrazuje.

=KDYŽ($A$1=NEPRAVDA;NEDEF();PRAVDA)

Jak prakticky využít fukci NEDEF jsem popsal v samostatném článku: Zobrazovat/skrývat/ zvýrazňovat datové řady (křivky) v grafech.

KDYŽ a matice

Perfektní využití má funkce KDYŽ je i v maticovém počtu, jako podmínka.

Microsoft Excel matice podmínky s KDYŽ

Využít KDYŽ v maticích je možno několika způsoby, některé jsou vhodnější některé méně (napřílad u výpočtu PRŮMĚRU). Pokud se budete chtít dozvědět o maticích více doporučuji sekci s články o maticích (od zadání po praktické použití ve výpočtech).

=SUMA(KDYŽ(C5:C8="M";1;0)*(F5:F8)) =SUMA(KDYŽ(C5:C8="M";(F5:F8);0)) =SUMA(KDYŽ(C5:C8="M";(F5:F8)))

Více informací o maticích

Jak prakticky využít fukci KDYŽ v maticích jsem popsal v článku: Matice a výpočty včetně podmínek.

KDYŽ a kontrola textů - COUNTIF(S)

Obsahuje buňka hledaný text?

=KDYŽ(COUNTIF(B5;"koruna*");"obsahuje";"neobsahuje") =KDYŽ(COUNTIF(B5;"*koruna*");"obsahuje";"neobsahuje") =KDYŽ(COUNTIF(B5;"*koruna");"obsahuje";"neobsahuje") Microsoft Excel podmínky s COUNTIF(S)

Více informací o COUNTIF(S)

Jak prakticky využít fukce COUNTIF(S) v článku: COUNTIFS, nebo COUNTIF.

Microsoft Excel - stahuj logo

Ke stažení zdarma

Soubor s ukázkami funkce KDYŽ ke stažení ZDARMA:


Závěrem

Máte-li k funkci KDYŽ doplnění, můžete použít komentáře.

Článek byl aktualizován: 29.01.2016 13:31

Odměna

Ušetřil vám tento web čas, peníze? Pomohl vyřešit problém? Jste ochotni poskytnout symbolickou odměnu na další rozvoj? Vybrte si formu odměny, která vám vyhovuje.


Pavel Lasák

Pavel Lasák - autor webu

Microsoft Office (Word, Excel, PowerPoint) se věnuji od roku 2006. Své vědomosti a zkušenosti dávám k dispozici na různých školeních a konzultacích, ale také na tomto webu. K dispozici na tomto webu je mnoho návodu, tipů a triků včetně desítek různých šablon.

   Pavel Lasák LinkedIn Profil    Pavel Lasák Google+ Profil    Pavel Lasák facebook Profil    Pavel Lasák twitter Profil

Doporučte tento článek přátelům

Pokud vám článek pomohl, případně si myslíte, že může pomoci i někomu dalšímu, budu rád když jej sdílením doporučíte přátelům - děkuji:



Komentáře


Jarda

Přidáno: 08.08.13 12:55

Zdravím, možná by bylo lepší u příkladu s číselným rozsahem uvést možnost elegantního řešení např. pomoci UDF funkce s využitím konstrukce SELECT CASE.

Autor Pavel Lasák: Odkaz na konstrukci SELECT CASE byla doplněna do článku.

Kája

Přidáno: 19.10.13 11:51

Ahoj, mám dotaz chci v excelu napsat kód(VB) který by porovnal údaje ve dvou listech... a nevím jak na to - chtěl jsem použít funkci if :-) díky k.

Josef

Přidáno: 24.10.13 17:51

pomůžete mi prosim vás s příkladem? Mám vytvořit funkci MIN s funkcí IF

Autor Pavel Lasák: Bylo doplněno do článku.

Pavel Lasák

Přidáno: 25.10.13 21:48

To Josef: Najít v tabulce B2:D10 ve sloupci D minimální hodnotu jen v řádcích, které ve sloupci B se shodují s B15. =MIN(IF(B2:B10=B15,D2:D8)) pro český Excel =MIN(KDYŽ(B2:B10=B15;D2:D8)) Zadávat jako maticový vzorec.

Pavel Lasák

Přidáno: 27.10.13 08:45

Jak na kombinace funkcí MIN a KDYŽ jsem doplnil do článku.

Jiří Beran

Přidáno: 27.10.13 10:10

Zajímavý článek, jen u těch příkladů kde se přiřazuje písmeno na základě číselného intervalu by možná chtělo uvést, že se to dá řešit mnohem elegantněji a přehledněji přes VLOOKUP, pokud nastavím poslední parametr jedničku.

Pavel Lasák

Přidáno: 27.10.13 16:29

To Jiří Beran: Děkuji za postřeh, doplnil jsem. Ono možnosti jak jeden úkol vyřešit je mnohdy několik. Záleží co člověk umí, jaké má zkušenosti, kolik má času. Možnosti řešení jednoho úkolu za použití několika různých funkcí jsme sepsal v článku: Jaký vzorec (funkci) použít?

Pavel Lasák

Přidáno: 12.11.13 14:41

Doplnil jsem možnost jak řešit problému při formátování roku, tak aby šablona fungovala v Excelu českém i anglickém. Využívá k funkci KDYŽ i funkci HODNOTA.NA.TEXT

Karolína

Přidáno: 30.12.13 12:15

Dobrý den, potřebovala bych drobnou radu. Mám dvojité kódování projektových nákladů - nejprve kód projektu a potom specifický kód nákladů v rámci linky. Ve velkém souboru, kde je pohromadě několik projektů a velké množství projektových nákladů, bych potřebovala vytvořit automaticky seznam všech nákladů jednoho projektu. Nicméně jak projektový, tak specifický kód se opakují (např. náklad za nákup benzínu je vždy AH01 - projekt, BE010201 a během měsíce jich máme třeba 20). Přes funkci KDYŽ spojenou s funkcí SVYHLEDAT jsem vždy schopná najít pouze jednu linku v listu, i když jich tam mám třeba 10. Nějaké návrhy? Děkuji!

Monika

Přidáno: 30.12.13 17:38

Dobrý den, mám vytvořit v tabulce zda je plat nad průměrný. průměrný, nebo podprůměrný. Mám tam zadány různé hodnoty. Když vím že průmětný plat je 11000 Kč. Jak teda mám vytvořit vzoreček ?

JardaH

Přidáno: 13.01.14 16:05

Dobry den, je moznost kombinace s funkci suma? Mam sloupec hodnot a kazda hodnota se nachazi v urcitem stavu rozpracovanosti (definovano textem v sousednim sloupci). Ja bych potreboval, abych mi vzorec scital pouze hodnoty ve stejnem stavu rozpracovanosti. Dekuji.

Pavel Lasák

Přidáno: 14.01.14 18:20

To JardaH: Nevím jak vypadá tabulka, nepostačí funkce COUNTIF?

Efklor

Přidáno: 19.01.14 19:18

Dobrý den. Poraď mi prosím s mým problémem. Do této funkce mohu zapsat podmínku maximálně 8x. Já ale potřebuji třeba i 15x. Dá se to nějak zapsat?. =KDYŽ(B1=C1;D1;KDYŽ(B1=C2;D2;KDYŽ(B1=C3;D3;KDYŽ(B1=C4;D4;KDYŽ(B1=C5;D5;KDYŽ(B1=C6;D6;KDYŽ(B1=C7;D7;KDYŽ(B1=C8;D8)))))))) Pokud pokračuji v zápisu =KDYŽ(B1=C1;D1;KDYŽ(B1=C2;D2;KDYŽ(B1=C3;D3;KDYŽ(B1=C4;D4;KDYŽ(B1=C5;D5;KDYŽ(B1=C6;D6;KDYŽ(B1=C7;D7;KDYŽ(B1=C8;D8;KDYŽ(B1=C9;D9))))))))) Po potvrzení zápisu mi ohlásí, že "Napsaný vzorec obsahuje chybu". Děkuji za pomoc.

Honza

Přidáno: 19.01.14 23:26

Dobrý den, mám podobný problém. Maximální povolený počet vnoření pro funkci KDYŽ je 8x. Já potřebuji 12x. Mám Excel 2010, kde by měl být počet vnoření až 64x. Při dalším vnoření mi po potvrzení program hlásí chybu - Určený vzorec nelze zadat, protože používá více úrovní vnoření, než lze v aktuálním formátu souborů zadat.

Pavel Lasák

Přidáno: 20.01.14 20:27

To Honza: Nutno uložit sešit v nové verzi (*.xlsx) zavřít a znovu otevřít.

Lucka

Přidáno: 15.02.14 20:41

Dobrý den, nevíte náhodou jak za pomoci funkce dentýdne a když napsat příklad tak, aby pokaždé vyšlo číslo pro den Po - 1; Út - 2...?

Pavel Lasák

Přidáno: 16.02.14 06:55

To Lucka: Nepomůže nastavit vlastní formát buňky na "ddd"? Pro když využít vnořní funkcí popsáno výše v kapitole: "Když - více podmínek".

Bára Brožů

Přidáno: 27.02.14 10:12

Dobrý den, mám dotaz - potřebuji použít funkci IF, aby mi vyhodnotila, zda kontroly stavu byly provedeny v noci nebo ve dne. V zadané tabulce to mám ale ve formátu např. BR/05/14 pro den a BR/05/14/N pro noc - N značí noc. Je vůbec možné, aby si Excel vybral data, která končí /N, popřípadě jak mám funkci napsat, nebo se bude muset vytvořit další sloupec, kde to bude přímo specifikováno? Mockrát Vám děkuji.

Pavel Lasák

Přidáno: 01.03.14 19:56

To Bára Brožů: Například pomocí textové funkce DÉLKA zkontrolovat, zda buňka obsahuje 10 znaků, pokud ano jedná se o noc.

Tom Brož

Přidáno: 13.03.14 23:10

Pěkný den, potřebuji aby se mi na základě vyplnění data a směny vypsalo jestli je daná směna ranní či noční (3denní cyklus ráno noc) Př: 1.1.2014 Sm B 3. noční 2.1.2014 Sm A 1. ranní 2.1.2014 Sm D 1. noční 2.1.2014 Sm C tato směna má právě volno!! Jde to přes funkci když? Díky moc.

Karel

Přidáno: 03.04.14 12:01

dobrý den, nevím si rady jak napsat funkci pro tento příklad. V buňce A1 může být uvedeno číslo, text, ale i text a číslo rozdělené "/" na libovolné pozici. Potřebuji aby se podle formátu buňky A1 v buńce B2 dosadila hodnota. Např: A1=text = B1=1; A1=číslo = B1=2; A1= text,lomítko,číslo = B1=3 Děkuji vám za pomoc

Petr

Přidáno: 12.04.14 21:34

Dobrý den, mám na vás dotaz, jaký vzorec mám použít na tento případ? Potřebuji dostat do excelovské tabulky tyto hodnoty z faktur, tzn. jedna faktura = jeden řádek. 1. sloupec = datum vystavení faktury, např. 5.1.2013 2. sloupec = datum splatnosti faktury, např. 19.1.201 3. sloupec = částka z faktury 4. sloupec = 1. den roku, např. 1.1.1213 5. sloupec = 2. den roku, 2.1.2013 atd. Potřeboval bych, aby ve sloupcích mimo uvedené časové období 5. - 19.1.2013 byly buď nuly nebo prázdné buňky a ve sloupcích v časovém období 5. - 19.1.2013 byla uvedena částka faktury, např. 100 000 Kč. Bohužel nevím, jaký vzorec použít. Díky za brzkou pomoc.

anna

Přidáno: 23.04.14 16:00

dobrý den, mám za úkol sestavit funkci KDYŽ a do ní zakombinovat finkci max .... jedná se přesněji o to, že máme úkol (hodnocení žáků) prospěl s vyznamenáním a máme tam zadat podmínku že tam nesmí být číslo větší jak 3, prospěl a neprospěl. předem díky za rady

Jojo

Přidáno: 25.06.14 08:47

To Efklor: Doporučujem použiť =SVYHLEDAT(B1;C1:D9;2;NEPRAVDA)

Jojo

Přidáno: 25.06.14 09:55

To Karel: =KDYŽ(JE.ČISLO(A1);2;KDYŽ(JE.CHYBA(NAJÍT("/";A1));1;3))

Jojo

Přidáno: 25.06.14 10:14

To Anna: =KDYŽ(A1<=3;"prospěl s vyznamenáním";KDYŽ(A1=4;"prospěl";"neprospěl"))

Přidáno: 01.07.14 15:48

Dobrý den, předně chci velice poděkovat za vaše návody. Chtěla bych vás požádat o radu s příkladem uvedeným výše: =KDYŽ(A26=1;KDYŽ(A27="test";"Zadána jednička a slovo test.";"Zadána jen jednička.");KDYŽ(A27="test";"zadáno jen slovo test";"Nezadáno nic co je požadováno.")) Místo textu "Zadána jednička a slovo test." a dalších bych potřebovala, aby byla počítána hodnota ze dvou buněk na dvou listech. Když jsem do funkce místo textu zadala klasický vzorec s odkazem na buňky, funkce mi jako výsledek vždy předložila popis vzorce, nikoliv výsledek. Zkoušela jsem vnořit i funkci HODNOTA, ale bezvýsledně. Děkuji předem! Lenka

Jojo

Přidáno: 09.07.14 09:02

To Lenka: Ak rozumiem správne otázke, tak riešením je zadať názov listu pred A26 alebo A27 (napr.=KDYŽ(List2!A26=1; ...)

Narayaen

Přidáno: 09.07.14 13:55

Dobrý den, trápím se syntaxí příkladu vícenásobné podmínky. Mám 3 intervaly (0;5000), (5001;10000) a (100001;15000). Pokud číslo v buňce bude vyhovovat prvnímu intervalu, tak jej vynásobit 0,14, pokud druhému, tak 0,16, pokud třetímu, tak 0,18. Mohli byste mi pomoct prosím? Děkuji

Jojo

Přidáno: 16.07.14 10:06

To Narayaen: -- Predpokladám, že prišlo k preklepu(správne má byť asi 10001 a nie 100001). Potom riešením by bolo toto: -- =KDYŽ(A1<0;"menšie ako 0";KDYŽ(A1<=5000;A1*0,14;KDYŽ(A1<=10000;A1*0,16;KDYŽ(A1<=15000;A1*0,18;"väčšie ako 15000")))) -- Texty v úvodzovke je možné samozrejme zmeniť/vymazať --

Jitka

Přidáno: 22.07.14 12:11

Dobrý den, prosím o radu, jak psát červeně v buňce, když je aktuální datum v buňce R26 (podle vzorce =DNES() ) o dva a více dnů vyšší než v buňce C6 (kde bylo zadáno manuálně v čase prvního vyplňování); dokud běží interval datum plus dva dny, píše se text modrým písmem. Děkuji. Hezký den.

Jojo

Přidáno: 24.07.14 08:31

To Jitka: -- Predpokladám, že bunka C6 sa má vyfarbovať. Potom sa treba nastaviť na túto bunku, zvoliť Podmienený formát/Vzorec + zadať: -- =R26-C6>2 a vybrať požadovanú farbu písma alebo pozadia.

Pavel Lasák

Přidáno: 30.07.14 16:40

To Jojo: Díky za odpovědi a pomoc čtenářům tohoto webu.

Tomas

Přidáno: 07.08.14 16:30

Ahoj, ve sloupci (20položek) mám písmena A,B,C. Potřeboval bych spočítat kolik mám A, B a C ve výsledku. Děkuji

Pavel Lasák

Přidáno: 07.08.14 17:16

To Tomas: Funkce COUNTIF http://office.lasakovi.com/excel/funkce/countif-funkce-statisticke-excel/

Tomas

Přidáno: 08.08.14 10:30

To Pavel: Děkuji.

Alexandra

Přidáno: 10.08.14 12:50

Dobrý den, mám spíše obecný dotaz. Můžu fci KDYŽ využít i v případě, kdy potřebuji mít podmínku, že pokud se čísla ve sloupci A budou rovnat, tak chci to číslo, které bude mít ze sloupce B nejaktuálnější datum? Tzn když budu mít ve sloupci A tři 22 a ve sloupci A ke každé 22 jiné datum, chci, aby mi to našlo tu hodnotu, kde je datum max.

Pavel Lasák

Přidáno: 13.08.14 20:11

To Alexandra: Nutno využít ještě funkci MAX, Případně SVYHLEDAT, přesně jsem nepochopil co má Excel provést.

Šárka

Přidáno: 28.08.14 08:54

Dobrý den, potřebovala bych najít chybu ve vzorci pro kombinaci podmínek KDYŽ, vzorec mi nepočítá správně, když není splněna první podmínka více než 35, automaticky dává hodnotu z té druhé i když hodnota není v intervalu 30-36. Prosím, najdete mi chybu??? Děkuji. =KDYŽ(H11>35;10000;KDYŽ(36>H11>30;9000;KDYŽ(31>H11>25;7500;KDYŽ(26>H11>20;6000;KDYŽ(21>H11>15;4500;KDYŽ(16>H11>10;3000;KDYŽ(H11>4;1500;KDYŽ(H11<5;0))))))))

Jean

Přidáno: 29.08.14 16:11

Proč nefunguje funkce když(A1="*abc*";"text obsahuje abc") ale funkce countif(A1;"*abc*") funguje (vrátí 1)? funkce když má problém se zástupným znakem !?

Jojo

Přidáno: 02.09.14 08:30

To Jean: =KDYŽ(JE.CHYBA(NAJÍT("abc";A1));"bez abc";"text obsahuje abc")

Jojo

Přidáno: 02.09.14 12:52

To Šárka: POZOR upravil som pôvodné rozsahy, lebo sa prekrývali -- =KDYŽ(H11>35;10000;KDYŽ(H11>30;9000;KDYŽ(H11>25;7500;KDYŽ(H11>20;6000;KDYŽ(H11>15;4500;KDYŽ(H11>10;3000;KDYŽ(H11>5;1500;"číslo <= 5")))))))

Jojo

Přidáno: 03.09.14 08:19

To Pavel Lasák (Přidáno: 30.07.14 16:40): Som rád, že môžem pomôcť aj autorovi(odlahčiť prácu) aj čitateľom (uľahčiť prácu) a aj ma to baví, hoci v živote sú ďaleko dôležitejšie veci.

beden

Přidáno: 06.10.14 23:31

Ahoj, narazil jsem celkem do zdi, když jsem si programoval jednu tabulku. Potřeboval bych nějak naprogramovat funkci IF a to následujícím způsobem: Když buňka A1 bude obsahovat text XY, aby se zkopírovala hodnota buňky B1 do buňky C1. Lze to nějak? díky.

Jojo

Přidáno: 13.10.14 10:04

To beden: -- do "C1" vložiť: -- =KDYŽ(A1="XY";B1;"") -- (nerozlišuje malé/veľké písmená)

Daniel

Přidáno: 13.10.14 14:09

Dobrý den, potřeboval bych poradit, jak přiřadit jednotlivým časovým intervalům kvartály. Konkrétně, jak nastavit, aby se podle data v jedné buňce přiřazoval v druhé správný kvartál? Takže když bude v buňce například 10.2.2014 pak se přiřadí I., když bude v buňce datum 3.9.2014 pak se přiřadí III. Předem děkuji za pomoc.

Jojo

Přidáno: 14.10.14 08:17

To Daniel: -- Pre kvartál/štvrťrok viď komentáre pridané "10až13.10.14" na: -- http://office.lasakovi.com/excel/funkce/ms-excel-datum-a-cas-prehled/

Daniel

Přidáno: 14.10.14 14:01

Pomohlo. Děkuji.

Pavel

Přidáno: 05.11.14 15:22

Dobrý den, mám prosbu, pátrám po funkci, kdy potřebuji z několika listů sešitu zkopírovat řádek o několika sloupcích na 4. list za podmínky, že se v daném řádku zobrazí slovo chyba. Jde mi o to, aby ze všech listů, kde se v daných řádcích objeví slovo chyba zkopíroval řádek do listu chyba se všemi hodnotami uvedenými na daném řádku. Děkuji moc za rady.

Jojo

Přidáno: 07.11.14 13:01

To Pavel:Sub Test() 'Testuje 3 listy 'v 10 riadkoch a v 4 stĺpcoch hľadá slovo "Chyba" 'ak slovo nájde, tak daný riadok prekopíruje na 4.list rw2 = 2 ' výstup od riadku 2 (list4) For sh = 1 To 3 ' listy 1 až 3 For rw = 1 To 10 ' riadky 1 až 10 For col = 1 To 4 ' stĺpce A až D If Sheets(sh).Cells(rw, col) = "Chyba" Then ' hľadaný text Sheets(sh).Range("A" & rw & ":D" & rw).Copy Sheets(4).Cells(rw2, 1) ' kopírovať stĺpce A až D na list 4 Sheets(4).Cells(rw2, "E") = Sheets(sh).Name ' názov listu s chybným riadkom do stĺpca "E" rw2 = rw2 + 1 ' ďalší riadok Exit For End If Next col Next rw Next sh End Sub

Denisa

Přidáno: 11.11.14 12:16

Dobry den, potrebovala bych poradit ohledne nasledujiciho: kdyz cislo v bunce C5 je větší než 50000, tak bych potřebovala vypocitat 20% z castky C5 a kdyz C5 je mensi nez 50000, tak aby tam bylo cilso 0. Dekuji, Deni

Jojo

Přidáno: 13.11.14 08:48

To Denisa: -- Nakoľko nebolo uvedené, že aký má byť výsledok, keď sa rovná 50000, tak som dal, že 20% počíta, keď je väčšie alebo rovno 50000: -- =KDYŽ(C5>=50000;C5*0,2;0)

Pavel

Přidáno: 24.11.14 20:07

Dobry den , potreboval bych poradit s vypoctem v excelu v zavislosti na priznaku kdyz. Priklad : Sloupec C obsahuje popis polozky (napr.rohlik, chleba, mleko, polozky se budou nahodne opakovat po radcich), ve sloupci D je vzdy uvedena cena danne polozky. Jde o to jak jednoduse nastavit, aby napriklad v bunce F1 doslo k vypoctu a to tak ze projde cely sloupec C a kdyz se bude rovnat napr. slovu rohlik provede soucet vsech castek v bunkach v sloupci D pro slovo rohlik.

Jan M.

Přidáno: 26.11.14 10:13

Pane bože! Kterého dementa napadlo všechny fce počeštit?!?!?!

Jojo

Přidáno: 01.12.14 09:03

To Pavel: -- =SUMIF(C2:C10;"rohlik";D2:D10)

Marta S.

Přidáno: 19.12.14 10:01

Dobrý den, mám dotaz ohledně funkce když. Mám 2 sloupce, ve sloupci A mám unikátní jména(např všechna jména začínající na A), ve sloupci B mám ke každému unikátní číslo. Potřebuji aby v buňce C1 bylo univerzální číslo(např. pro všechna jména začínající A. A obdobně pro jména od B a tak dále. (jmen mám okolo 600, unikátních čísel taky, takže vypisovat všechny není v lidských silách) Děkuji za pomoc a přeji příjemný den =)

Martin K

Přidáno: 19.12.14 15:42

Dobry den , Mam dotaz. Jak udelat abych mel v B1 podminky ze kdyz v A1 bude A tak v bunce C1 bude 7 diky

Jojo

Přidáno: 22.12.14 07:40

To Marta S.: -- ak rozumiem dobre zadaniu, tak do C1: =KÓD(A1)

Marta S

Přidáno: 23.12.14 10:07

To Jojo - ne, myslela jsem to takto, abych nemusela vypisovat všechny unikátní čísla pro příklad: =KDYŽ(H3=699954;2,17;KDYŽ(H3=699955;2,17;KDYŽ(H3=699926;2,17;KDYŽ(H3=699925;2,17;KDYŽ(H3=699906;2,17;KDYŽ(H3=699905;2,17;KDYŽ(H3=699944;2,17;KDYŽ(H3=699945;2,17;KDYŽ(H3=699971;2,17;KDYŽ(699963=H3;2,17;KDYŽ(H3=700085;2,17;KDYŽ(H3=700084;2,17;KDYŽ(H3=699924;2,17;KDYŽ(H3=699923;2,17;KDYŽ(H3=699902;2,17;KDYŽ(H3=700426;2,17;KDYŽ(H3=699933;2,17;KDYŽ(H3=699934;2,17;KDYŽ(H3=699949;2,17;KDYŽ(H3=699948;2,17;0)))))))))))))))))))) atd. myslela jsem spíš jestli nejde označit nějak hromadně ty čísla, abych je tam nemusela zadávat tak složitě. Teď třeba zkouším funkci když s nebo, příklad: =KDYŽ(H3=NEBO(M18:M31);2,17;0) s tím, že v M18:M31 mám ty kódy, které potřebuji, ale nefunguje mi :-/

Marta S

Přidáno: 23.12.14 10:40

něco tady takovéhoto, ale nefunguje mi to =KDYŽ(NEBO(M18:M23;M25:M29)=$J$22;2;0), pořád mi to hází 0, i když J22=číslu, kt. je v buňkách M18:M23

Jojo

Přidáno: 29.12.14 13:08

To Marta S: -- nasledujúci vzorec treba vložiť cez CTRL+SHIFT+ENTER (nie cez samotný ENTER) -- =KDYŽ(NEBO(M18:M23=$J$22;M25:M29=$J$22);2;0)

Marta S

Přidáno: 02.01.15 17:18

To Jojo: Jojo, jsi absolutní bůh, když dorazíš do Výškovce, zvu tě na pivko nebo něco co piješ! :)

Jojo

Přidáno: 05.01.15 08:58

To Marta S: -- Nie, som len človek, tak ako ty

Mirda

Přidáno: 07.02.15 10:07

Potřeboval bych pomoc: Řeším příklad pomocí funkce "Řešitel" a potřebuji mu zadat podmínku, aby proměnná, kterou dosazuje byla buď =0 či =2 (či jinému číslu). Pomocí podmínek umím celé číslo, větší menší či rovno nějakému číslu, ale neumím m říci, aby dosazoval pouze dvě konkrétní čísla :(. Může mi někdo pomoci? Díky M.

Pavel

Přidáno: 17.03.15 09:42

Dobrý den, chtěl bych poprosit o radu. Vytvářím si tabulku pro výpočet ceny za dřevěnou konstrukci a potřeboval bych aby se mi provedl výpočet v dané buňce na základě těchto hodnot: Když v buňce B13 bude napásno ANO, aby se promítl do tohoto vzorce tento vzorec: =((B6-(B10*2))/1000) a přičetl tak hodnotu a pokud by bylo v B13 napsáno NE, aby nic dalšího nepřičítal. Vzorec vypadá takto: =((B6-(B10*2))*2/1000)+((B7-(B11*2))*2/1000) Vzorec vypočítá celkové potřebné množství profilu v metrech, potřebuji tedy ještě do vzorce doplnit podmínky vypsané výše. Velmi děkuji za Váš čas a pomoc. PŠ

Pavel Lasák

Přidáno: 19.03.15 20:31

To Pavel: Řešení pokud dobře chápu požadavek k ((B7-(B11*2))*2/1000) se při ANO přičítá:
=KDYŽ(B13="ANO";((B6-(B10*2))*2/1000)+((B7-(B11*2))*2/1000);((B7-(B11*2))*2/1000))
Předpokládám, že v B13 lze zadat jen ANO nebo NE.

johndoe

Přidáno: 10.04.15 17:02

Dobry den, mam dotaz. V jednom sloupci mam zadanu hodnotu splatek, napr. uveru a v druhem ppisemne vyjadreni kdo platit napr. P - petr, M - Michal. Jakou pouzit funkci aby se v jedne bunce pocitalo pouze kolik splatil Petr a v druhe bunce aby se pocitalo kolik splatil pouze Michal. Dekuji

Ace

Přidáno: 22.05.15 19:10

Dobrý den, mohu se zeptat, jestli lze pomocí funkce když vybarvit buňku? Například když buňka A1 = 0 pak vybarvi na žluto když A1 = 1 vybarvi na zeleno?

katka

Přidáno: 29.05.15 12:57

Dobrý den. Prosím o radu, jak zadat tuto funkci. Pokud bude den v týdnu sobota nebo neděle pak do sloupce "Když2" napište "Víkendový prodej", jinak nechte buňku prázdnou. Pokud bude cena za velké pivo nižší nebo rovna 17 Kč pak do sloupce "Když3" pomocí funkce KDYŽ napište "Výhodná koupě", jinak buňku proškrněte pomlčkou.

Martin

Přidáno: 24.06.15 14:30

Dobrý den, chtěl bych se zeptat jestli je možné vytvořit podmínku s datem kdy v buňce mám datum (formát 1-31) a v duňce vedle chci vrátit hodnotu v závislosti na tom který den v týdnu to je (po,út...). Npř.: 24.6.2015 (zobrazen jako 24) vrátí 2,5 (každou středu chci vrátit 2,5). Děkuji

Snup

Přidáno: 23.07.15 12:49

Dobrý den, mám dotaz , zda je možné přez tuto nebo i jinou funkci mazat identická čísla. Např. mám ve sloupci 6-9 5-8 6-9 4-6 potřebuji se nějakým způsobem zavit 6-9 tak aby tam toto číslo zůstalo pouze jednou Pokud je to možné předem dekuji za radu. :)

bara

Přidáno: 27.07.15 13:04

Dobrý den, chtěla bych se zeptat, jak v excelu zapsat toto řešení: Když sloupec buňka A1-A100 rovná se "slovo1" a současně buňka B1-B100 rovná se "slovo2", pak opiš příslušnou hodnotu ve soupci C.

Adam

Přidáno: 18.08.15 18:53

Dobrý den, prosím o radu s tímto problémem: ve sloupci B mám text ve kterém se náhodně vyskytují barvy modrá, červená, černá, žlutá. A já potřebuji aby se mi ve sloupci E vypsala barva, která je na tomtéž řádku právě ve sloupci B. Děkuji moc za nápady

Jarda

Přidáno: 22.08.15 07:20

to katka Pro první dotaz je vzorec =KDYŽ(DENTÝDNE(DNES();2)=6;"Víkendový prodej";KDYŽ(DENTÝDNE(DNES();2)=7;"Víkendový prodej";"")) Pro druhý dotaz je vzorec =KDYŽ(JE.PRÁZDNÉ(B3);"-";KDYŽ(B3<=17;"Výhodná koupě";"-")) JE.PRAZDNE musí ve vzorci být pro ošetření prázdné buňky, jinak ve sloupci "Když3" bude zobrazovat Výhodná koupě.

Jarda

Přidáno: 22.08.15 12:22

to Johndoe Váš dotaz by šlo řešit s pomocí VBA

Jarda

Přidáno: 22.08.15 12:28

to Ace Váš dotaz by šlo řešit ve VBA

Jarda

Přidáno: 22.08.15 12:32

to Martin Do buňky třeba B3 zadáte datum 2.9.2015 a v Formát buňek - Číslo - Vlastní zadáte do pole Typ d tím se vám z celého data bude zobrazovat jen 2. Do buňky C3 zadáte =DENTÝDNE(B3) a opět musíte v Formát buňek - Číslo - Vlastní do pole Typ zadat ddd a v Pondělí zobrazí po. Pokud by jste chtěl celý název dne v týdnu musíte zadat dddd. Do D3 zadáte tento vzorec =KDYŽ(DENTÝDNE(B3) = 4;2,5;""). Zde Formát buňek - Číslo - Druh: nechat formát buď Obecný a nebo zadat Číslo

Jarda

Přidáno: 23.08.15 07:45

to Adam Do sloupce E a stejného řádku kde máte barvu Modrou dáte tento vzorec =SVYHLEDAT(B3;B3:B8;1;NEPRAVDA) a v této buňce budete mít také barvu Modrou. Vzorec můžete rozkopírovat do dalších buňek.

Daniel

Přidáno: 24.08.15 09:30

Dobrý den, vytvářím ceník produktu který se da nejakym zpusobem sestavit z ruznych dílů. Např typ takový a makový, provedení takové makové atd. Mám u každého tohohle dílu prepinac navedeny na jedno urcite pole ve skupine. V tom poli se meni cisla podle zapnuteho prepinace. Chtel bych vedet jestli jde nejakym zpusobem zjednodusit zapis: =KDYŽ(A210=1;E209;KDYŽ(A210=2;E210;KDYŽ(A210=3;E212;KDYŽ(A210=4;E213;0))))), protoze vypisovat to a neustale překlikavat je k zblazneni :)

hana

Přidáno: 09.09.15 15:29

Ahoj, mám problém, nemohu přijít na to, proč mi tento vzorec nefunguje. Vše je v pořádku do doby, než začnu přidávat když(c13=10 atd. =KDYŽ(C13=9;KDYŽ(D13=1;20200;KDYŽ(C13=9;KDYŽ(D13=2;20500;KDYŽ(C13=9;KDYŽ(D13=3;20980;KDYŽ(C13=9;KDYŽ(D13=4;21630;KDYŽ(C13=9;KDYŽ(D13=5;22550;KDYŽ(C13=10;KDYŽ(D13=1;20350;"?"))))))))))))

Jarda

Přidáno: 10.09.15 11:56

to hana KDYŽ má syntaxi KDYŽ(podmínka;[ano];[ne]) máte v celém vzorci použito C13=9 celkem 5x a pokračujete dalším rozhodnutím jestliže ta podmínka je splněna, ale chybí vám ve vzorci rozhodnutí jestliže ta podmínka není splněna co má dělat. Vzorec jsem vám upravil takto =KDYŽ(C13=9;KDYŽ(D13=1;20200;KDYŽ(D13=2;20500;KDYŽ(D13=3;20980;KDYŽ(D13=4;21630;KDYŽ(D13=5;22550;KDYŽ(D13>5;"?";"?"))))));KDYŽ(C13=10;KDYŽ(D13=1;20350;"?");"?")) Pokud bude v C13 9 a v D13 1 - 5 zobrazí se čísla 20200 - 22550 a pokud v C13 10 a v D13 1 zobrazí se 20350 a pokud v D13 bude menší hodnota než 1 a větší než 5 zobrazí se ?. Pokud bude v D13 menší hodnota než 9 a větší než 10 zobrazí se ?.

L.

Přidáno: 14.09.15 17:02

Ahoj, potřebuju pomoci a vůbec si nevím rady... potřebuji funkci - když mám např. někde ve sloupci b číslo 10 tak, aby se mi sečetli všechny čísla ze sloupce c (tam kde je u b 10) a výsledek se napsal do pole např. k22 .... doufám že mě chápete a zároveň doufám, že taková funkce existuje :) Předem děkuji za pomoc P.S. Jsem úplný začátečník

Jarda

Přidáno: 18.09.15 16:50

to L. Funkce taková existuje, která vyhledá číslo, ale pokud číslo v buňce není vrací #N/A nenalezeno. Aby k tomu nedošlo použil jsem funkci KDYŽ. Tento vzorec vložte do buňky K22 =KDYŽ(JE.CHYBHODN(SVYHLEDAT(10;B:B;1;NEPRAVDA));"Není";KDYŽ(SVYHLEDAT(10;B:B;1;NEPRAVDA) = 10;SUMA(C:C);0)) Jestliže ve sloupci B bude číslo 10 zobrazí výsledek sloupce C a pokud ve sloupci B číslo 10 nebude zobrazí Není.

L. to Jarda

Přidáno: 24.09.15 10:55

Děkuji za pomoc, ale asi jsme se úplně nepochopili :) ve sloupci B mám různá čísla (často se opakují) , potřebuji, aby se mi sečetli hodnoty ze sloupce C, ale jen ty hodnoty, kde je v B např. číslo 10 (dále např. budu mít v B číslo 16, tak aby se sečetli hodnoty z C, ale jen ty, kde je v B číslo 16). Když vložím vzorec, který jste poslal, sčítá se mi úplně všechno. Děkuji

Jarda

Přidáno: 27.09.15 07:59

to L. To jsme se opravdu špatně pochopily. Existují dvě funkce SUMIF a SUMIFS, kterými lze váše zadání vyřešit. =SUMIF(B1:B50;10;C1:C50) nebo =SUMIFS(C1:C50;B1:B50;10). V tomto odkazu se můžete o těchto funkcích dozvědět více http://office.lasakovi.com/excel/funkce/sumif-sumifs-funkce-excel/

Libor

Přidáno: 30.09.15 08:00

Dobrý den. Existuje funkce, kde při nalezení textu v jedné buňce (Např A3) mi vloží do buňky (např A4) obrázek? Pro vysvětlení: Potřebuji v zakázkovému listu přiložit logo daného odběratele.

Martin

Přidáno: 05.11.15 13:13

Dobrý den, potřebuji poradit: když mám v jedné buňce číslo 1 tak aby do druhé buňky vložil text (např.text 1). Když číslo 2, tak text 2 ...Je možné použí t fukci KDYŽ, nebo něco jiného ?

Libor

Přidáno: 10.11.15 11:16

Pro Martina: Ahoj Martine, já bych volil místo vzorec, zformátovat cílovou buňku. Zvolit: Formát buňky v záložce Číslo - vlastní a zadat tento tvar "text "#0

Anna

Přidáno: 16.11.15 12:29

Dobrý den, moc prosím o radu - v jednom listu v D sloupci mám datumy ve formátu dd.mm.rr. V tom samém listu ve sloupci B mám hodnoty. Do jiného listu potřebuji dát vzorec obsahující podmínku - pokud najdeš v listu 1, ve sloupci D datum např. z 10. měsíce doplň hodnotu z řádku ve sloupci B. Jde to prosím nějak udělat? Jak definovat hledání celého měsíce a ne konkrétního datumu? Předem moc děkuji za odpověď, A.

Pavel Lasák

Přidáno: 30.11.15 19:47

To Anna: Zjištění měsíce pomocí fuknce MĚSÍC. =KDYŽ(MĚSÍC(D2)=10;B2;"")

Luke

Přidáno: 15.12.15 15:09

Zdravím, mám na Listu 1 pár údajů jako číslo zakázky, výrobek číslo atp. ve sloupci J mám seznam 5 textových hodnot přičemž jedna je Vyřešeno-Oprávněná Reklamace, pokud člověk zatrhne tuto hodnotu chtěl bych aby se celý řádek (číslo zakázky, výrobek číslo...atp) zapsal na další list věděl někdo jak na to ? (v konečné fázi úplně nejlepší by bylo aby se řádek po zvolení v seznamu hodnoty vyřešeno propsal na další list a nešel upravovat, až třeba po zvolení jiné hodnoty ze seznamu by zase šel upravit (aby např když člověk zapomene nějákou hodnotu z listu zapsat třeba číslo výrobku, tak aby musel pro opravu odkliknout jinný stav než vyřešeno kvůli integritě a kompletu dat. můj mail: Depo8@seznam.cz

Pavel Lasák

Přidáno: 28.12.15 16:17

To Luke: Tohle už je na VBA makro.

Tomáš

Přidáno: 13.01.16 11:50

Dobrý den, prosím o radu. V jedné buňce(např. C7) mám pomocí ověření dat vytvořený rozevírací textový seznam. Nyní potřebuji vytvořit podmínku pro jinou buňku (C6), kdy v případě, že do C7 vyberu hodnotu "A", v C6 se mi nabídne textový seznam "AA", pokud zvolím do C7 "B" tak do C6 se mi nabídne seznam "BB" atd. Děkuji T.

Pavel Lasák

Přidáno: 26.01.16 08:58

To Tomáš: Jak na to jsem popsal závislé seznamy

heavenlee

Přidáno: 12.02.16 09:15

Dobrý den, poradí mi někdo, jak sečíst přesčasy? V tabulce mám hodnoty celých hodin (8,10,11 nebo 12). Potřebuju zjistit pouze celkový součet toho, co je navíc. Funguje mi to u jedné buňky (jeden den), ale když zvolím celou oblast (30dnů-30buněk), je vzorec neplatný. Už je mi z toho horko :-(

Pavel Lasák

Přidáno: 20.02.16 14:58

To heavenlee: Využít funkci SUMIF nebo SUMIFS, pokud je podmínek více. NEbo využít další sloupec do kterého na základě podmínky vložím potřebnou hodnotu přesčasu a pak pomocí SUMA sečtu.

Pepa

Přidáno: 09.03.16 08:47

Dobrý cen, chtěl sem se zeptat, umí Excel udělat: když nesplním podmínku vytvoř řádek a pokračuj dál. Děkuji za odpověď

Honza

Přidáno: 03.04.16 20:08

Dobrý večer, jak by jste udělali pomocí funkce když a seznamu. vyberu Pohlaví: (Muž,Žena) a automaticky se mi změní i Stav (Svobodný, rozvedený, ženatý, vdovec) ; (Svobodná, rozvedená, vdaná, vdova). Formou seznamu? Děkuji za odpověd.

Pavel

Přidáno: 25.04.16 13:42

Dobrý den. Mám v tabulce řadu čísel a písmen. Ve chvíli kdy je v buňce písmeno potřebuji, aby se mi do výsledné buňky připočetla 10. To znamená: mám 10 buněk v osmi z nich jsou různá čísla a ve dvou je písmeno P. Ve výsledné buňce potřebuji mít hodnotu 20.

Jarda

Přidáno: 30.04.16 14:43

to Pavel Do výsledné buňky zadáte tento vzorec =SUMA(COUNTIF(A1:A10;"P")*10) samozřejmě s jiným rozsahem buněk.

Tomáš M.

Přidáno: 11.05.16 23:48

Dobrý den, potřeboval bych poradit jak upravit vzorec: {=ROUNDUP(MAX(KDYŽ((Tabulka_Tools_1[[Stroj]:[Stroj - záloha 2]]=$D7)*(Tabulka_Tools_1[Materiál 1]=E$3)*(Tabulka_Tools_1[Outsourcing]<>PRAVDA);Tabulka_Tools_1[Spotřeba/hodinu mat 1]));0)} Funkce je: pokud v tabulce souhlasí stroj a zároveň Materiál 1 a outsourcing není pravda tak přiřadí číslo ze sloupce spotřeby a pak udělá maximum a zaokrouhlí. A tento vzorec bych potřeboval upravit aby když stroj souhlasí i s materiálem 2 a outsourcing není pravda aby přiřadil číslo ze sloupce spotřeby 2 a pak z mat 1 i mat 2 udělal maximum maximum. Nějak na toto nemůžu přijít. Za jakoukoliv radu předem děkuji

Jarda

Přidáno: 29.06.16 08:27

to Tomáš M. Myslím, že by to mohlo být takto, ale nemám možnost to jak koliv odzkoušet. {=ROUNDUP(KDYŽ(A((Tabulka_Tools_1[[Stroj]:[Stroj - záloha 2]]=$D7)*(Tabulka_Tools_1[Materiál 1]=E$3)*(Tabulka_Tools_1[Outsourcing]<>PRAVDA);(Tabulka_Tools_1[[Stroj]:[Stroj - záloha 2]]=$D7)*(Tabulka_Tools_1[Materiál 2]=F$3)*(Tabulka_Tools_1[Outsourcing]<>PRAVDA))=PRAVDA;Tabulka_Tools_1[Spotřeba/hodinu mat 2];0)&-MAX(mat1)&-MAX(mat2);0)

Radek Pýcha

Přidáno: 19.07.16 08:43

Dobrý den, dokáže funkce IF také vypsat hodnotu nějaké buňky kde se nachází text? Udělal sem si jednoduchý přepínač ve formuláři (respektive dva přepínače, které jsem propojil s buňkou kde se mi pak vrací 1 nebo 2 podle toho co člověk zaškrtl). Jde mi o to, že když by byl výsledek přepínače 1 potřeboval bych vypsat text (v podstatě zkopírovat) který je v jedné buňce, a to samé u zaškrtnutí druhé volby. Možná na to jdu moc složitě a je pro to nějaké jiné řešení. Ve funkcích se moc neorientuji :/// Děkuji, pokud se rozhodnete mi někdo pomoci

Hana

Přidáno: 04.08.16 08:22

Mám tabulku a chci vytvořit funkci a nevím si rady. V jednom sloupci mám datum splatnosti, ve druhém splatnost a ve třetím způsob úhrady. Zvládla jsem udělat vzorec, který mi ve sloupci splatnost hlásí, že faktura je po splatnosti =KDYŽ((DNES()>=F19);"po splatnosti";"") a když je stále ve lhůtě, je pole prázdné, ale problém je, že bych funkci chtěla rozvinout tak, aby mi při doplnění způsobu úhrady (dobírkou, hotově, převodem) ve sloupci splatnost také funkce hlásila, že je faktura zaplacena. Můžete mi prosím poradit?

Jarda

Přidáno: 23.08.16 07:55

to Hana Funkce Když se dá rozvíjet takto =Když((DNES()>=F19);"po splatnosti";Když(podmínka;ano;Když(podmínka;ano;ne);ne 2.podmínka);ne 1.podmínka)

Roman O.

Přidáno: 14.09.16 10:43

Zdravím, velmi by jsem potřeboval poradit s následujícím případem: mám výpočet průměru z buněk a jestliže hodnota buněk je 0, tak díky funkci když se mi zobrazí pomlčka "-". Potřeboval by jsem do této funkce však ještě zakomponovat podmínku, že jestliže v úplně jiné buňce (P35) je nula, tak se průměr nespočítá a bude také zobrazena pomlčka "-". Již jsem zkoušel dost pokusů, ale bohužel mne již nic nenapadá Současný vzorec kam potřebuji nakomponovat výše uvedenou podmínku: =KDYŽ(AVERAGEA(P9:P28)=0;"-";AVERAGEA(P9:P28))

Roman O.

Přidáno: 14.09.16 10:45

Předem děkji za případné odpovědi. :) S přáním pěkného dne Roman O.

Jarda

Přidáno: 17.09.16 08:04

to Roman O. Vzorec podle vašeho přání může být upraven takto =KDYŽ(JE.ČISLO(P35)=0;"-";KDYŽ(AVERAGEA(P9:P28)=0;"-";AVERAGEA(P9:P28)))


Přidání nového komentáře

Poznámka: Z časových důvodu není v mých sílách zodpovědět všechny dotazy. Děkuji za pochopení.




(vlož číslo padesátpět)

Z bezpečnostních důvodu dočasně nemůžete použít HTML značky, kromě <code> a </code> (pro vkládání VBA kódu). Děkuji za pochopení.
Děkuji, za Vaše komentáře.

Za obsah komentářů neodpovídám, jelikož jsou komentáře publikovány ihned po jejich napsání čtenářem. Toto nemohu nijak ovlivnit. Přesto si vyhrazuji možnost jakýkoli neslušný komentář smazat bez udání důvodu. V komentářích si tykáme. ;-)





Excel


Sdílejte

Pomohl Vám návod?
Sdílejte na Facebooku, G+
LinkedIn...

Nové články


Newsletter

Přihlaste se odběru novinek a získejte:
Ebook zdarma -
10 kroků ke zvládnutí (Word, Excel, PowerPoint)
Šipka Kniha 3D Více o ebooku ...

TOPlist Licence Creative Commons webarchiv rss XML

Stránky o MS Office (Excel) produktu společnosti Microsoft. Neslouží jako technická podpora.
| Email na autora: pavel.lasak@gmail.com | Copyright © : Pavel Lasák 2004 - 2016 | 133843

Tento web zatím neprošel jazykovou korekturou. Beta verze redakčního systému.