Přeskočit navigaci | Přeskočit na novinky
     

Jste zde: Úvodní stránka » excel » funkce » svyhledat-funkce-excel

SVYHLEDAT (VLOOKUP) - funkce Excel

Videokurzy Excel

Ve spolupráci se SEDUO jsem vytvořil několik videokurzů:

Jak využít funkci SVYHLEDAT (VLOOKUP) v Microsoft Excel.

Od teoretického úvodu, přes syntaxi až po praktické příklady (jsou ke stažení zdarma).

Doplněno: 30.1.2016 o kapitolu jak SVYHLEDAT použít pro více zdrojových tabulek

Přehled kapitol o funkci SVYHLEDAT

Tento článek jsem z důvodu přehlednosti rozdělil do samostatných kapitol:

Chlap ve školce: "Dobrý den, přišel jsem si pro dítě."
"A které?"
"A není to jedno? Stejně ho zítra ráno zase přivedu."

Poznámka: Tuto funkci zkouší většina personalistů, když zjišťují zda "umíte" Excel.

Úvodem do SVYHLEDAT

Funkce SVYHLEDAT vyhledá prvním sloupci tabulky zadanou hodnotu a vrátí hodnotu buňky ve stejném řádku jiného sloupce dané tabulky.

Ukázka

Určím, co a ze kterého sloupce chci získat.

MS Excel 2010 - SVYHLEDAT - ukázka

Například dosazení hodnot do objednávky ze seznamu výrobků (viz praktický příklad v dalším textu).


Syntaxe SVYHLEDAT

Funkce SVYHLEDAT (anglicky název: VLOOKUP) vyhledá v prvním sloupci tabulky požadovanou/hledanou hodnotu a vrátí hodnotu, která je ve stejném řádku (jako nalezená hodnota), ale nachází se v jiném (námi určeném) sloupci zdrojové tabulky.

Syntaxe v české verzi

SVYHLEDAT(hledat; tabulka; sloupec [;typ])

Syntaxe v anglické verzi

V anglické verzi Excelu, je oddělovačem čárka ne středník.

VLOOKUP(hledat, tabulka,sloupec [,typ])

Popis atributu funkce:

  • hledat - hodnota (číslo, logická hodnota, odkaz), hledaná v prvním sloupci tabulky.
  • tabulka - prohledávaná tabulka u které je první sloupec prohledáván. Argument tabulka může být odkaz na oblast nebo název oblasti.
  • sloupec - je celé číslo sloupce v argumentu tabulka, ze kterého se bude přiřazovat. Lze zadávat od 1 až max. hodnoty počtu sloupců v tabulce (tabulka). První sloupec má hodnotu 1.
  • typ nepovinný parametr - nabývá logických hodnot (0 - NEPRAVDA - FALSE, 1 -PRAVDA - TRUE).
    • PRAVDA - (nezadáno/prázdné) - přesná shoda nebo nejvyšší hodnotu, která je menší než hledaná.
    • NEPRAVDA - vrátí hodnotu pokud najde přesnou shodu.

Volba funkce z karty vzorce

Pokud funkci vyberete na kartě Vzorce v sekci Knihovna funkcí funkce Vyhledávací a referenční obdržíte následující dialogové okno:

MS Excel 2010 - funkce svyhledat vvyhledat

Poznámky:

Písmeno S v názvu funkce SVYHLEDAT znamená sloupec/svisle. Tj. hledaná data musí být ve sloupcích napravo od požadované hodnoty v prvním sloupci Pro anglické VLOOKUP, kde V jako vertikální.

Hodnoty v prvním sloupci prohledávané tabulky musí být seřazeny vzestupně, jinak funkce SVYHLEDAT vrací nesprávné hodnoty!

Nerozlišuje malá a vleká písmena (ač by se někdy hodilo).

Existuje-li v prvním sloupci tabulky více shodných hodnot, funkce SVYHLEDAT vrátí nevýše nalezenou hodnotu (první od konce/spodu).

Funkce SVYHLEDAT a VVYHLEDAT jsou podobné (stačí pochopit jednu, druhá je analogická). Rozdíl je v tom, máte-li data ve sloupcích, použijete (SVYHLEDAT). Pokud jsou data v řádcích, použijete (VVYHLEDAT).

Zpět na seznam kapitol o funkci SVYHLEDAT.

Přiřadit zaměstnance

Mám osobní čísla (Id zaměstance), kterým náleží odměna a tabulku se všemi zaměstanci s jejich osobním číslem (ID) a jménem. Já potřebuji do tabulky doplnit jejich jména.

Zdrojové tabulka

Mám Excel ve kterém mám dvě tabulky, první do které budu vkládat funkci. Jedná se o seznam oceněných zaměstanaců, kde již mám jejich osobní čísla (Id zaměstannec). Druhá tabulka je zdrojová, tabulka obsahuje zaměstance seřazené podle jejich osobního čísla (ID zaměstance) a v dalších sloupcích je jméno daného zaměstance a třeba oddělení ve kterém pracuje.

Zdrojová tabulka funkce SVYHLEDAT Excel

Řešení

Potřebujete vložit jméno. Využijete funkci SVYHLEDAT. Z předchozí kapitoly již víte jakou syntaxi funkce SVYHLEDAT má, takže ji vyplníte, Označíte buňku B2 a vložíte do ní funkci:

Syntaxe pro připomenutí: SVYHLEDAT(hledat; tabulka; sloupec [;typ])
  • hledat - Z cílové tabulky odkaz osobní číslo zaměstance (ID), tj. buňka A2
  • tabulka - oznsačíte zdrojovou tabulku, doporučuji všechny sloupce (zaměstanci mohou přibývat. Takže zadáte E:G (zdrojová tabulka je mezi sloupci E:G a ve sloupci G je osobní číslo zaměstnance)
  • sloupce - číslo sloupce ve kterém je jméno, tj. 2. E je první sloupec, F je druhý sloupec a je v něm jméno (pro oddělení by byl sloupec 3, je jako třetí).
  • typ - 0 neboli NEPRAVDA - která zajistí, že Excel najde přesnou shodu. číslo zaměstance které hledáte se musí v tabulce nacházet přesně ve stejném tvaru (hodnotě).

Takže byste měli mít zadáno:

=SVYHLEDAT(A2;E:G;2;0)

Funkci již stačí rozkopírovat.

Řešení ukázka

Výsledek funkce SVYHLEDAT Excel

Řešení hotovo

Po rozkopírování dostanete:

Výsledek funkce SVYHLEDAT Excel

Procvičení

Jako procvičení si můžete do tabulky doplnit i oddělení oceněných zaměstanců.

Dodací list - pomocí SVYHLEDAT

Potřebujete-li vytvořit dodací list, kdy jen vyplníte ID výrobků a automaticky se vám doplní jeho název, prodejní cena.

Zdrojová tabulka

Předpokládám, že máte k dispozici tabulku s prodávanými výrobky, kdy ID je unikátní pro každý výrobek. Tabulka může obsahovat i jiné údaje (nákupní cena), které se dají využít v jiných výpočtech (obchodní marže).

Zdrojová tabulka funkce SVYHLEDAT Excel 2010

Řešení

Pro zjištění názvu výrobku na základě udaného ID.

=SVYHLEDAT(A7;$A$18:$G$25;2;NEPRAVDA)

Pro zjištění ceny výrobku na základě udaného ID. Pozor, nutno počítat i sloučené sloupce, takže jde o sloupec 7 (ne jak by na první pohled zdálo 3).

=SVYHLEDAT(A7;$A$18:$G$25;7;NEPRAVDA) Zdrojová tabulka funkce SVYHLEDAT Excel 2010

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT - Dodací list soubor ve formátu *.xlsx soubor pro Excel 2007 a novější.

Zpět na seznam

Tabulka přímo ve funkci

Tabulku můžete do SVYHLEDAT zadat i přímo do funkce. Použitá konvence:

  • oddělovače
    • {} začátek a konec pro vkládaní tabulky
    • ; oddělovat hodnot v daném řádku tabulky
    • | přechod na nový řádek v tabulce
  • vlastní data v tabulce
    • "Leden" - textové hodnoty do uvozovek
    • 1 - číslené hodnoty se zapisuji přímo

Zdrojová tabulka

Tabulka kterou vytvoříme bude vypadat:

Leden 1
Únor 2
Březen 3
Duben 4
Květen 5
Červen 6
Červenec 7
Srpen 8
Září 9
Říjen 10
Listopad 11
Prosinec 12

Výše uvedenou tabulku lze přepsat na:

{"Leden";1|"Únor";2|"Březen";3|"Duben";4|"Květen";5|"Červen";6|"Červenec";7|"Srpen";8|"Září";9|"Říjen";10|"Listopad";11|"Prosinec";12}

Ve funkci SVYHLEDAT bude pak vypadat:

=SVYHLEDAT(C4;{"Leden";1|"Únor";2|"Březen";3|"Duben";4|"Květen";5|"Červen";6|"Červenec";7|"Srpen";8|"Září";9|"Říjen";10|"Listopad";11|"Prosinec";12};2;NEPRAVDA)

V buňce C4 bude zadávaná hodnota názvu měsíce (Leden, Únor, ...) výsledkem bude pořadové číslo měsíce.

Poznámka: Využivá někdo prakticky tento zápis? Osobně jsme jen nepoužil, ale pár dotazu jsem obdržel. Mám totiž dojem, že jde jen o testovací otázku na zkouškách. Holt cihlu do ruky nevezme, ale odborník to je ;)

Jak zjistit jmeniny pomocí SVYHLEDAT

Úkolem je podle zadaného dne a měsíce dohledat jméno osoby, která má v tento den jmeniny.

Zdrojová data

Pro tvorbu tabulky budou potřeba zdrojová data. Můžete je stáhnout z internetu například na http://svatky.pitevna.cz/seznam-svatku/ po menší úpravě obdržíte podobnou tabulku.

Poznámka: Cvičně si můžete vytvořit i druhou tabulku, ve které se bude hledat datum jmenin, na základě zadaného jména.

MS Excel 2010 - Úvodní obrazovka

Řešení

Tabulku máte tak není nic jednoduššího než napsat správně funkci SVYHLEDAT.

Pro nalezení jména osoby, která má jmeniny:

=SVYHLEDAT(B5;B8:C384;2)

Pro získaní data jmenin pro zadané jméno můžete zkusit samostatně, nebo opsat tento vzorec:

=SVYHLEDAT(E5;E8:F384;2)

Takže nic těžkého. A navíc už nezapomenete na jmeniny své drahé polovičky. Já to mám jednoduché 11.12. (dobře se to pamatuje).

Trik

Pokud do buňky, kde se zadává datum zadáte funkci:

=DNES()

Po spuštění Vám Microsoft Excel sdělí, kdo má aktuální den narozeniny :).

Sešit ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT - jak zjistit jmeniny. soubor ve formátu *.xlsx

Zpět na seznam kapitol o funkci SVYHLEDAT.

Doplnit cenu dle váhy

Máte tabulku s hmotnosti zásilky a cenou za přepravu. V řešení potřebujete, abyste po zadání hmotnosti přepravovaného zboží obdržely cenu za přepravu. Tj. hmotnost je udána ve skocích. Hmotnost přepravovaného zboží a k tomu cena.

MS Excel 2010 - funkce svyhledat

Řešení příkladu

Ukázka za použití funkce SVYHLEDAT najde vhodnou cenu za přepravu. Použijeme v typu PRAVDA, jelikož půjde o přibližné hledání. Tj. pro 123,3 kg musí funkce SVYHLEDAT najít vhodnou sazbu.

Poznámka: Pozor u hmotností, je uvedena cena od. Tj. pozor ať se vám ceny neposunou o řádek!

=SVYHLEDAT(D6;A5:B10;2;PRAVDA)

Stejného výsledku dosáhnete, když (typ) - tj. PRAVDA vynecháte.

=SVYHLEDAT(D6;A5:B10;2)

Poznámka: Tento úkol lze řešit i pomocí logické funkce KDYŽ. V tomto článku, jde o ukázku použití funkcí SVYHLEDAT.

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT přeprava soubor ve formátu *.xlsx

Označit řádky splňující podmínku

Máte k dispozici tabulku a potřebujete označit řádky, které mají požadovaný datum (v ukázkovém příkladu 3.2.2011), pokud v daném řádku je požadované datum, obdržíme text ANO. Jak na to?

MS Excel 2010 - funkce svyhledat vvyhledat

Ukázka řešení. Na konci článku je příklad ke stažení zdarma.

Platí pro sloupec "C" =SVYHLEDAT(A5;$H$6:$H$6;2;NEPRAVDA)

Řešení má nevýhodu, že v případě, že není splněno hledané kritérium, funkce vrátí chybovou hodnotu #NENI_K_DISPOZICI. Toto můžete obejít doplněním funkce SVYHLEDAT o funkci IFERROR.

Platí pro sloupec "D" =IFERROR(SVYHLEDAT(A5;$H$6:$I$6;2;NEPRAVDA);" ")

Poznámka: Pokud zapomenete ve funkci SVYHLEDAT uvést argument NEPRAVDA, hodnotu ANO budete mít i u novějšího Data (datum).

Ukázka pro sloupec "E" =SVYHLEDAT(A5;$H$6:$I$6;2)

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT - pokud je splněna podmínka přeprava soubor ve formátu *.xlsx

Další možnosti použití: Kontrolovat zda je zboží na skladě.

SVYHLEDAT jako maticový vzorec

Automaticky přiřadit cenu do faktury. Máte tabulku výrobku a potřebujete doplnist automaticky cenu. V pomocné tabulce je k dispozici jméno výrobku a jeho cena. Při psaní vzorce chceme využít maticový vzorec.

MS Excel 2010 - svyhledat maticově

Řešení příkladu

Před použitím funkce SVYHLEDAT označte celou oblast, pro kterou bude použít maticový vzorec (v ukázkovém příkladu to je A5:A18). Ve funkci SVYHLEDAT doplníte patřičné argumenty.

=SVYHLEDAT(A5:A18;D8:E11;2)

Pro vložení maticového vzorce nutný stisk Ctrl + Shift + Enter a je hotovo.

Poznámka: Podrobněji co jsou matice a jak na ně v Microsoft Excelu jsem sepsal v článku: Matice úvod - Microsoft Excel.

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT maticově soubor ve formátu *.xlsx

SVYHLEDAT - tabulka pomocí definovaného názvu

Potřebujete-li se odkázat na tabulku (buňku) pomocí definovaného názvu oblasti (buňky). Toto ukázkové řešení předpokládá, že tabulka ve která se hledá má název "MojeOblast" a v buňce F5 je zadáno MojeOblast, poté se stačí jen odkázat na tuto tabulku pomocí funkce NEPŘÍMÝ.ODKAZ.

=SVYHLEDAT(F2;NEPŘÍMÝ.ODKAZ(F5);2)

Příklad

MS Excel 2010 - funkce svyhledat - definovaný název

Poznámka: Znáte-li nějaké elegantnější řešení, jak se ve funkci SVYHLEDAT odkázat ne definovaný název oblasti, můžete uvést v komentářích.

SVYHLEDAT dvě podmínky

Potřebujete-li hledat v tabulce na základě dvou podmínek. Ve ukázce, mám první podmínku osobu (jméno prodavače) a druhá podmínka čtvrtletí, výsledkem bude hodnota prodeje.

Ukázka řešení

Pro zdrojovou tabulku vytvoříme pomocný sloupec, kde obě podmínky sloučíme (musí být zajištěno, že hodnoty budou jedinečné).

Vyhledávací dotaz lze sloučit B6&C6

=SVYHLEDAT(B6&C6;$A$10:$D$21;4;NEPRAVDA) Excel 2010 - SVYHLEDAT dvě podmínky

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT dvě podmínky soubor ve formátu *.xlsx

SVYHLEDAT dvě podmínky (křížení)

Potřebujete-li hledat v tabulce na základě dvou podmínek, které se vzájemně kříží. Ve ukázce, mám první podmínku prodávaný výrobek a druhá podmínka je měsíc, ve kterém se prodávalo, výsledkem bude hodnota prodeje.

Ukázka řešení

Pro řešení využijete funkci POZVYHLEDAT, které určí na základě podmínky (měsíc) číslo sloupce ve kterém se bude hledat.

=SVYHLEDAT(B6;$A$10:$G$15;POZVYHLEDAT(C6;$A$9:$G$9;0);NEPRAVDA) Excel 2010 - SVYHLEDAT dvě podmínky

Ke stažení

Ke stažení zdarma: Funkce SVYHLEDAT dvě podmínky - křížení soubor ve formátu *.xlsx

SVYHLEDAT více zdrojových tabulek

Obdržel jsem zajímavý dotaz, jak spojit více tabulek pro funkci SVYHLEDAT. Řešení je několik (třeba přes maticové vzorce, IFERROR), já si vybral řešení s využitím funkce JE.NEDEF a funkce KDYŽ.

Jak funguje? Při nenalezení hodnoty funkci SVYHLEDAT obdržíte chybovou hodnotu #NENÍ_K_DISPOZICI, funkce JE.NEDEF zobrazí PRAVDA , NEPRAVDA v jakém stavu je výsledek funkce. No a samotná funkce KDYŽ už jen zobrazí hodnotu z příslušného listu. Protože máme listy tři, je potřeby funkci KDYŽ vnořovat. Pro ukázku funkce, ať nemusíte opisovat ;)

=SVYHLEDAT(C15;ListA!A:B;2;0) =KDYŽ(JE.NEDEF(SVYHLEDAT(C21;ListA!A:B;2;0));"Není v listu";"Je v daném listu") =KDYŽ(JE.NEDEF(SVYHLEDAT(K28;ListA!A:B;2;0));KDYŽ(JE.NEDEF(SVYHLEDAT(K28;ListB!A:B;2;0));SVYHLEDAT(K28;ListC!A:B;2;0);SVYHLEDAT(K28;ListB!A:B;2;0));SVYHLEDAT(K28;ListA!A:B;2;0))

Další řešení přes IFERROR, Děkuji za inspiraci Jirka Beran.

=IFERROR(SVYHLEDAT(C26;ListA!A:B;2;0);IFERROR(SVYHLEDAT(C26;ListB!A:B;2;0);SVYHLEDAT(C26;ListC!A:B;2;0)))

Další možnost je vylepšit o odkaz na buňky ve kterých budou názvy listů atd.

Ukázka

Excel - SVYHLEDAT více zdrojových tabulek

Ke stažení

V přípravě

Chyby a jejich odstranění

Při odlaďování vašich tabulek s funkcí SVYHLEDAT můžete narazit na problémy.

Syntaktické chyby

Musíte opravit syntaxi, Pozor při kopírování ukázek, anglické verze Microsoft Excelu používají čárku (,), české středník (;).

Nesprávné seřazení

Hodnoty v prvním sloupci prohledávané tabulky musí být seřazeny vzestupně, jinak funkce SVYHLEDAT vrací nesprávné hodnoty!

Malá hodnota

Pokud je hledaná hodnota menší než nejmenší hodnota v prvním sloupci tabulky, vrátí funkce SVYHLEDAT chybovou hodnotu #N/A (záleží na typ).

Argumentu sloupec

Špatně nastaven argument sloupec, menší než 1, vrátí funkce SVYHLEDAT chybovou hodnotu #HODNOTA!. Nebo pokud je hodnota argumentu sloupec větší než počet sloupců v oblasti tabulka, vrátí funkce SVYHLEDAT chybovou hodnotu #REF!.

Zpět na seznam kapitol o funkci SVYHLEDAT.

Doplňující informace

  • V EN verzi Excelu a VBA je název funkce VLOOKUP (vertical).
  • Položky v druhé tabulce (tj. z které se vyhledává) doporučuji řadit abecedně.
  • Tabulky pro funkci SVYHLEDAT mohou být v různých listech

Související články:

Jak nahradit SVYHLEDAT v Excel

Jak nahradit SVYHLEDAT

Například když "referenční" sloupec není v prohledávané tabulce jako první. Řešením je použití funkci INDEX a POZVYHLEDAT. Podrobněji je uvedeno v samostatném článku, včetně sešitu ke stažení zdarma:


Závěrem

Zvládáte používat funkci SVYHLEDAT? Máte nějaký zajímavý příklad použití? Můžete doplnit do komentářů.

Článek byl aktualizován: 30.01.2016 21:34

Odměna

Ušetřil vám tento web čas, peníze? Pomohl vyřešit problém? Jste ochotni poskytnout symbolickou odměnu na další rozvoj? Vybrte si formu odměny, která vám vyhovuje.


Pavel Lasák - autor webu

Pavel Lasák

Microsoft Office (Word, Excel, PowerPoint) se věnuji od roku 2000 (od 2004 ne této doméně) - Roku 2017 jsem od Microsoft získal prestižní ocenění MVP (zatím jsem jediný z ČR v kategorií Excel). Své vědomosti a zkušenosti dávám k dispozici také na on-line videích pro SEDUO. Školím a konzultuji, učím na MUNI. Hlavně tvořím tento web. Je zde k dispozici přes 1.000 návodu, tipů a triků včetně stovek různých šablon, sešitů.

   Pavel Lasák LinkedIn Profil    Pavel Lasák Google+ Profil    Pavel Lasák facebook Profil    Pavel Lasák twitter Profil


Komentáře


Jan N.

Přidáno: 29.08.13 11:12

Dobrý den, jak postupovat v případě, že existuje v prvním sloupci tabulky (kde má probíhat hledání) více shodných hodnot. Jedná se o následující příklad: tři rozdílné údaje (např. název zakladatele firmy) mají shodná IČ. Je třeba přiřadit ke stejným IČ všechna tři jména. Dá se použít nějakým způsobem funkce svyhledat?

Pavel Lasák

Přidáno: 29.08.13 17:38

To Jan: SVYHLEDAT najde první od konce, a pak pokud je více stejných hodnot (COUNTIF). Doplnit další data přes funkci POSUN a logi funkci KDYŽ. Jednu funkci, která to vše zvládne sama neznám.

Jan N.

Přidáno: 02.09.13 13:31

To Lasák: Moc děkuji za odpověď.

Tomáš N.

Přidáno: 16.10.13 17:20

Dobrý den, řeším jak složit funkci svyhledat s podmínkou. V prvním sloupci mám čísla objednávek a do druhého přiřazuji jejich stav (hotovo,rozpracovano) z 2 sheetu. Chtěl bych to dát do makra, jen neumím zadat aby funkce svyhledat jela na stejný řádek kde je poslední hodnota ve sloupečku "A". Umím to zadat fixně třeba na 500 řádků, ale to je tam pak mnoho "NA#" vyplněných polí. Děkuji za radu.

Ondřej

Přidáno: 18.02.14 14:00

Dobrý den, potřeboval bych poradit jak vyřešit násleedující problém. V tebulce používám funkci vlookup pro buňku C2. Na tuto buňku potom odkazuji další vlookup(C2,....) Zde nastává problém nejspíše kvůli toho že excel neví kterou funkci má udělat dříve. V druhém použití vlookup není schopný vyčíst hodnotu buňky C2. Pokud místo C2 použiju junou buňku kam ručně vepíšu hodnotu, vše je ok ale pokud odkazuji na C2 jakkoli není možné hodnotu vyčíst (REF). Prosím o radu

Ivan

Přidáno: 26.02.14 17:41

Dobrý den,řeším problém se seznamem v excelu kdy potřebuji vyhledat určité číslo v seznamu-ve sloupci A a to tak,aby mě nyhledávání přesunulo rovnou na uvedené číslo,bohužel se mi to nedaří.Vyzkoušel jsem téměř všechny možnosti a při hledání o radu na internetu jsem narazil na váš veb. Jde vůbec řešit můj problém? Děkuji za radu

Pavel Lasák

Přidáno: 26.02.14 19:03

To Ivan: Přesunout se přímo do dané buňky? To bude potřeba využít VBA (makra).

Jarmil

Přidáno: 15.03.14 09:04

Dobrý den, mám menší problém. Dám příklad: mám tabulku s hodnotama kde jsou tři sloupce. Vprvním sloupci jsou některé hodnoty stejné, druhý a třetí jsou jiná. v druhém sešitu zadám hodnotu prvního a druhého sloupce a podle toho jak se budou shodovat automaticky přiřadí třetí hodnotu (auto - je červené - proto bude cena 100Kč, nebo auto - je zelené - proto cena bude 120Kč). Jde to pomocí fce SVYHLEDAT? Zatím na to nějak nemohu přijít. Děkuji

Pavel Lasák

Přidáno: 16.03.14 20:05

To Jarmil: Tu třetí hodnotu bude přiřazovat odkud (třetí sloupec)?

Jarmil

Přidáno: 17.03.14 11:51

Ano, třetí hodnota bude automaticky vkládána ze třetího sloupce ( v závislosti na barvě auta). Děkuji

Pavel Lasák

Přidáno: 17.03.14 18:30

Jarmil: Osobně bych spojil do dalšího sloupce přes funkci CONCATENATE (stejně tak hledanou hodnotu) a přes SVYHLEDAT bych hledal v tomto sloučeném sloupci.

Jarmil

Přidáno: 18.03.14 18:47

To Lasak. Děkuji za tip, už jsem to vyzkoušel a je to super.

Pavel Lasák

Přidáno: 18.03.14 20:01

To Jarmil: Rádo se stalo.

Tomáš

Přidáno: 07.08.14 13:43

Dobrý den, mám dotaz, možná to tu zaznělo, asi jsem tomu neporozuměl. Mám soubor se slovíčky, který je tvořen 3 sloupci (1. české slovo, 2.výslovnost, 3. slovo v jiném jazyce). Jde mi o to, že bych si chtěl udělat vyhledávač, když napíši např. česky slovo dům, aby mi to přiřadilo anglické slovo. To jsem zvládl přes SVYHLEDAT. Jenže problém nastává při tom, když jsou k jednomu českému slovu 2 slovíčka. SVYHLEDAT vyhledá pouze to první a to druhé už ne. Můžete mi poradit vzorec, jak to udělat, aby mi tedy k 1 českému slovu přiřadil dvě anglická slovíčka? Děkuji.

Pavel Lasák

Přidáno: 07.08.14 17:16

To Tomáš: Nevím jak je tvořena tabulka, šla by použít funcke POSUN a KDYŽ.

Tomáš

Přidáno: 08.08.14 11:28

Tabulka je tvořena takto: řád. A B C 1 česky výslovnost anglicky 2 doma at home 3 inside 4 indoors

Tomáš

Přidáno: 08.08.14 11:33

Buňka A1 - česky, B1 - výslovnost, C1 - anglicky A2 - doma, ------- C2 - at home C3 - inside C4 - indoors Bohužel to do komentářů nejde jinak napsat....

Tomáš

Přidáno: 08.08.14 12:01

A ještě by mě zajímalo jak se udělá funkce, která by data umístěné v buňkách na jednom řádku a 100 sloupcích rozdělila do 3 sloupců o n řádcích. Jde o to, že jsem si zkopíroval data a ty se mi v excelu uložily do jednoho řádku a já je potřebuji rozdělit do 3 sloupců... Děkuji.

Tereza

Přidáno: 18.10.14 16:33

Zdravím, mám tabulku, kde mám sloupec s ID produktu které vypadá např. takto ID_TRB1234. A vedle mám doplnit funkci, která by na základě toho vyhodila, o co se jedná. Tyto data mám v samostatné tabulce, kde je vypsáno např. toto TRB trouba. Použila bych funkci SVYHLEDAT ale to funguje jen u přesných hodnot. Což já tam mám tu hodnotu jakoby schovanou v textu. Poradíte mi prosím? Děkuju moc

Jojo

Přidáno: 20.10.14 08:14

To Tereza: -- ak bude ID_TRB1234 na Liste1 v stĺpci A, "TRB" na Liste2 v stĺpci A a "trouba" v stĺpci B a vždy sa bude jednať o 3 znaky za "ID_", tak -- =SVYHLEDAT(ČÁST(A1;4;3);List2!A1:B10;2;NEPRAVDA)

Andrea

Přidáno: 24.01.15 10:11

Dobrý den. nejprve bych vám chtěla moc poděkovat za úžasné stránky! není den, abych na nich něco nehledala:). jsou krásně napsané. co se týče mého dotazu. Potřebuji v práci použít funkci SVYHLEDAT, ale místo jedné buňky potřebuji doplnit celý řádek (cca 30 sloupců), který splnil kritérium vyhledání. Samozřejmě mohu v každé buňce pracně dělat stejný vzorec se změnou buňky, ale věřím spíš, že nějaká taková funkce existuje. Jen se mi ji nedaří zjistit. Moc děkuji za pomoc.

Pavel Lasák

Přidáno: 24.01.15 21:42

To Andrea: Zapsat funkci s využitím relativních a absolutních odkazů a vzoreček rozkopirovat.

Lucia

Přidáno: 02.02.15 07:11

Dobrý deň! Mám otázku k tejto funkcii, konkrétne k hodnote TYP - pravda, alebo nepravda. Mám časový rad pracovných dní, ku každému dňu je priradená určitá hodnota. Ja potrebujem zistiť touto funkciou pondelkové hodnoty, problém nastáva, keď je sviatok, tým pádom nemám hodnotu - aby mi táto funkcia zapísala utorkovú (resp. ďalší pracovný deň najbližší), lenže keď dám TYP=true, tak mi zapíše hodnotu k pondelku najbližšiu, ale spätne branú-t.j. piatkovú. Je možné toto vyriešiť? Ďakujem dopredu za odpoveď!

Jaromír

Přidáno: 03.02.15 17:50

Dobrý den, Z řešitele dostanu číselnou hodnotu, kterou zaokrouhlím na násobek 10. Toto číslo nebo jeho nejbližší hodnotu potřebuji najít datové oblasti cca 55 řádků a 25 sloupců. Hodnoty v jednotlivých buňkách představuji čísla, která se skládají z násobku čísla "a" a součtu násobku čísla "b". (n*a + n*b).Všechna čísla v dat. oblasti končí na 0. (v literatuře se objevuje funkce VYHLEDAT.NEJBLIŽŠÍ HODNOTU, ale syntaxe nikde).Předem děkuji za radu. 3.2.15. Jaromír

Štěpánka N.

Přidáno: 09.03.15 06:52

Dobrý den pane Lasáku, mám na Vás jako na odborníka dotaz. Jakou fci v Excelu mám použít,když potřebuji, aby se mi v novém sloupci zobrazila data ze zvoleného sloupce, dle zadaných kritérií? Příklad: Pokud vyhledáš ve sloupci A jméno "Jan", napiš toto jméno do zvoleného sloupce. V opačném případě uveď "není". Ještě lepší by bylo, kdyby se tam dalo nadefinovat, pokud najdeš text ve sloupci A dle zadaných kritérií, napiš do zvoleného sloupce 1, pokud ne, napiš 0. Předem děkuji za odpověď. Zdraví. ŠN

Pavel Lasák

Přidáno: 25.04.15 22:25

To Štěpánka: Využít funkcí COUNTIF a KDYŽ.

Hel

Přidáno: 24.05.15 17:51

Dobrý den, prosím o radu - potřebuji v tabulce vyhledat výraz, který je uveden v buňce se zadaným řetězem více podobných výrazů oddělených čárkou a mezerou, a pomocí SVYHLEDAT přiřadit výraz z dalšího sloupce ve stejném řádku. Více výrazů uvedených v té dané buňce není seřazeno abecedně a je jich tam i několik desítek. Děkuji předem, Hel

Blanka

Přidáno: 15.07.15 00:03

Nevím, jak se vypíná AdBlock.. pomůže někdo?

Daniel

Přidáno: 29.09.15 13:58

Dobrý den, Vyhledávání hodnoty zadaného pole probíhá vždy v 1.sloupci výběru? Níže v příkladu ve sloupci A18:A25? =SVYHLEDAT(A7;$A$18:$G$25;2;NEPRAVDA) Jak postupovat v případě, že potřebuji pracovat se sloupcem, který není první? Například (Vás SVYHLEDAT - dodací list): Co když sloupec ID bude poslední za sloupcem POZNÁMKA? Moc děkuji za odpověď. Daniel

JT

Přidáno: 26.10.15 06:41

Pavle moc Vám děkuji za super návody... Proč uvádíte "Hodnoty v prvním sloupci prohledávané tabulky musí být seřazeny vzestupně, jinak funkce SVYHLEDAT vrací nesprávné hodnoty!"? Máte to sám ozkoušené? Nebo jste to jen od někoho převzal?

Tomas

Přidáno: 02.11.15 18:40

Dobrý den. Chci se jen zeptat jak použít funkci SVYHLEDAT v případě, že mám určitou hodnotu stejnou pro více položek? Např. mám ve sloupci zadáno rohlík1, rohlík2, rohlík3, bageta, chleba, houska a potřebuji aby mi ukázalo kolik mám rohlíků, kolik baget a kolik housek. Doufám že jsem to napsal alespoň trochu srozumitelně. Děkuji

Iva

Přidáno: 11.11.15 17:09

Dobrý den, potřebovala bych poradit, jakou funkci mám použít na spočítání marže, rabatu a kombinace? V zadání mám úlohy, ale nesmím je spočítat na kalkulačce, ale v excelu. Předem děkuji za odpověď.

Peter

Přidáno: 23.11.15 19:08

Dobry den, potreboval bych vratit hodnotu treba do C sloupce, pokud jsou sloupce A,B v jednom listu stejne jako A,B v druhem listu. Jde mi zatim pouze "svyhledat" s jednim t.j. A sloupcem. Potrebuju ale i podminku s B sloupcem. Neco jako jmeno a prijmeni...mnoho jmen stejnych, i prijmeni ale zadny jedinec stejneho jmena. Dik predem.

Ivo

Přidáno: 24.11.15 14:12

Dobry den. Bohuzel vase vysvetleni je ve vetsine pripadu dost nesikovne a laik se v tom absolutne nevyzna.

Martin

Přidáno: 13.01.16 14:31

Zdravím, prosím o radu. Potřebuji do jedné tabulky dotahovat data z jiné (ze zdrojové). Normálně bych použil svyhledat, ale já potřebují vyhledat hodnotu, která je cca v prostředním sloupci tabulky a dotáhnout k tomu hodnotu, která je v prvním sloupci tabulky, takže svyhledat nepůjde... Díky moc za radu

Roman

Přidáno: 19.01.16 16:07

Ahoj všem. Používám Excel 2013. Mám: List1, Sloupec A (jména), seřezena stejně jako v listu2 Sloupec B,C,D, atd, pojmenované (T-62A, Obj. 140) atd... List2, sloupec A (jména), sloupec B,C,D atd... V listu2 jsou na řádcích u každého jména v buňkách B2:AH30 hodnoty, např: B2= IS-7, B3=T-62A atd..., hodnoty jsou na řádcích pořád stejné, ale pokaždé v jiné buňce. Potřebuji vyhledat v listu2 hodnotu, která odpovídá hodnotě (název sloupce B2 v listu1) a opakovat pro všechny hodnoty (názvy sloupců).

Lubo

Přidáno: 25.01.16 19:06

Prosim o radu. Mam stlpec udajov (mena klientov), pricom medzi jednotlivymi menami sa mozu nachadzat aj prazdne bunky. Ako by som vedel zistit posledne meno v stlpci? Neviem si s tym poradit. Za pomoc vopred dakujem :-)

Pavel Lasák

Přidáno: 30.01.16 21:34

To Lubo: Upravit tabulku, nebo využít VBA http://office.lasakovi.com/excel/vba-listy-bunky/radky-sloupce-excel-vba-kody/ nebo využít maticově =INDEX(A:A;MAX((A:A<>"")*(ŘÁDEK(A:A))))

Valina

Přidáno: 31.01.16 13:00

Dobrý den, chtěla bych Vás požádat o radu. Snažím se předělat sklad, aby se mi z listu s objednávkami automaticky odečítalo zboží ze skladu. 1. list objednávky, 2. list sklad. pomocí SVYHLEDAT se mi podaří nalézt pouze 1. objednávku, ale další kusy se mi již nepřičítají. Mohl byste prosím poradit, jak na to? Předem moc děkuji.

Valina - doplnění dotazu

Přidáno: 31.01.16 13:28

...jen doplním, co se týče skladu, měl by mít sloupce příjem, výdej a konečný stav. Zde se bavíme o výdejovém, jde mi tedy o odečítání (ne přičítání, jak jsem chybně uvedla). Děkuji

Jmeniny

Přidáno: 22.02.16 19:11

Dobrý den, funkce u "jmenin" není správně. I po stažení souboru, se mi nezobrazují správná jména. Prosím o korekturu. Děkuji

Jirka

Přidáno: 20.07.16 17:20

Dobrý den. Mám tabulku s ligami a příslušnými týmy. Na jiném listě bych chtěl výběrem bunky "ověření dat"-"seznam" výběrem ligy a pomocí dalších buněk se zadáním VVyhledat vypsat příslušné týmy ve vybrané lize. Pokud zadám funkci VVyhledat vypíše se mi tam něco jiného. V příloze posílám sešit se zadáním. https://uloz.to/!HCN6Pasug/vvyhledat-zadani-xlsx

Lucie

Přidáno: 18.08.16 12:51

Dobrý den, narazila jsem na problém, dokázal by mi někdo poradit? Mám několik tabulek se jmény a u každého jména počet hodin daného pracovníka. Jedno jméno se může vyskytovat klidně ve více tabulkách ale zároveň nemusí. Potřebuji na jiném listu vytvořit tabulku se seznamem všech jmen a sumou hodin daného pracovníka ze všech potřebných tabulek. Předem nevím, jaká jména se tam kdy objeví/připíší, zatím to mám pouze jako "pracovník 1" atd... Musím připravit danou tabulku s výpočty tak, aby fungovala při vyplnění jakýchkoliv jmen (tím jsem vyřadila např. SUMIF)... Šla jsem na to přes SVYHLEDAT ale narazila na dva problémy: - nemám hodnoty ve zdrojových tabulkách abecedně (a ani mít nebudu, jména se připisují pod sebe bez ohledu na abecední zařazení) - pokud se jméno v dané tabulce nevyskytne, ale v ostatních ano, funkce mi nesečte pouze ty, kde hodnoty najde ale vrátí hodnotu "není k dispozici". Děkuji za rady.

Jojo

Přidáno: 22.08.16 07:36

To Lucie: -- cez kontingenčnú tabuľku alebo makro

Eva

Přidáno: 31.08.16 12:56

Dobrý den, můžete prosím poradit jak zadat do fce SVYHLEDAT odkaz na tabulku v jiném listě pomocí proměnného odkazu? Mám hodnoty v tabulkách na jednotlivých listech podle čísla kalendářního týdne a potřebuji z nich udělat souhrny do měsíčních přehledů. Chtěla bych to zadat tak, abych nemusela ve funkci měnit číslo týdne a tím odkaz na list ve kterém se má vyhledávat, ale bohužel se mi to nedaří. Za radu předem děkuji.

Michal

Přidáno: 07.09.16 17:59

Zdravím narazil jsem dokument který popisoval maticovou funkci "FindTextArray" která jakoby nahrazuje filtr, respektive vypisuje seznam duplicitních hodnot a k nim lze stejně tak vypsat přiřazené hodnoty z dalšího sloupce. Problém je, že to v českém prostředí nefakčí a nemůžu dohledat ekvivalent. Neřešil jste už někdo? Děkuji

Jojo

Přidáno: 09.09.16 09:34

To Michal: -- asi by pomohlo, keby sa tu uviedla tá pôvodná funkcia, alebo si pozrieť: -- http://office.lasakovi.com/excel/funkce/ms-excel-funkce-cz-en/

Michal

Přidáno: 09.09.16 10:24

Ta funkce je uváděná jako "=FindTextArray(;;)" a právě ten překlad nemůžu najít.

Jojo

Přidáno: 12.09.16 08:45

To Michal: -- Nebolo k tomu ešte nejaké makro?






Excel


Sdílejte

Pomohl Vám návod?
Sdílejte na Facebooku, G+
LinkedIn...

Nové články


Newsletter

Přihlaste se odběru novinek a získejte:
Ebook zdarma -
10 kroků ke zvládnutí (Word, Excel, PowerPoint)
Šipka Kniha 3D Více o ebooku ...

TOPlist Licence Creative Commons webarchiv rss XML

Stránky o MS Office (Excel) produktu společnosti Microsoft. Neslouží jako technická podpora.
| Email na autora: pavel.lasak@gmail.com | Copyright © : Pavel Lasák 2004 - 2017 | 103811

Tento web zatím neprošel jazykovou korekturou. Beta verze redakčního systému.