LAMBDA - praktické vlastní funkce v Excel

Praktické funkce pro LAMBDA

V tomto článku se dozvíte jak napsat praktické funkce s využitím funkce LAMBDA. Zatím jsou k dispozici tyto:

• Výpočet plochy obdelníků a obvodu
• Počet slov
• Velikonoce
• Čtvrtletí
• Bodové hodnocení - využití KDYŽ (IF)
• Související články
• Ke stažení

Další budou postupně přibívat.

Výpočet plochy a obvodu obdelníku

Začneme zlehka, výpočet plochy obdelníků a následně obvod.

Výpočet plochy

Funkce napřímo - bez použití LAMBDA - na vyzkoušení

=B8*C8

Funkce LAMBDA v listu

=LAMBDA(x;y;x*y)(B7;C7)

Funkce LAMBDA v s využitím Definovaného názvu

=PlochaObdelnik(B6;C6)

Výpočet obvodu obdelníku

Funkce napřímo - bez použití LAMBDA - na vyzkoušení

=2*(B25+C25)

Funkce LAMBDA v listu

=LAMBDA(x;y;2*(x+y))(B24;C24)

Funkce LAMBDA v s využitím Definovaného názvu

=ObvodObdelnik(B23;C23)

Počet slov

Potřeba spočítat počet slov, kdy využijeme finty, že spočteme počet mezer a přičteme jedničku (samozřejmě nejprve pročistíme o mezery navíc). Budeme u kdy ve složitejším případě, může být buňka i prázdná, a nebudete chcít v

Funkce napřímo - bez použití LAMBDA - na vyzkoušení, bohužel nepočitá s prázdnou buňkou

=DÉLKA(PROČISTIT( B7))-DÉLKA(DOSADIT(B7;" ";""))+1

Funkce LAMBDA v listu, bez kontroly prázdné buňky

=LAMBDA(Text; DÉLKA(PROČISTIT( Text))-DÉLKA(DOSADIT(Text;" ";""))+1)(B10)

Funkce vylepšena o kontrolu zda je prázdná

=DÉLKA(PROČISTIT( B14))-DÉLKA(DOSADIT(B14;" ";""))+KDYŽ(DÉLKA(PROČISTIT(B14))>0;1;0)

Funkce vylepšena o kontrolu zda je prázdná, bez když pouze za využití porovnání

=DÉLKA(PROČISTIT( B14))-DÉLKA(DOSADIT(B14;" ";""))+KDYŽ(DÉLKA(PROČISTIT(B14))>0;1;0)

Funkce LAMBDA s kontrolou na prázdnou buňku

=LAMBDA(s;DÉLKA(PROČISTIT(s))-DÉLKA(DOSADIT(s;" ";""))+(DÉLKA(PROČISTIT(s))>0))(B18)

Funkce LAMBDA v s využitím Definovaného názvu

=PocetSlov(B19)

Velikonoce

Díky inspiraci na webu (https://spreadsheetpage.com/), lze vypočítat Velikonoce (přesněji Velikonoční pondělí) pro zadaný rok.

Funkce napřímo - bez použití LAMBDA - na vyzkoušení

=(KČ(("4/"&B5)/7+MOD(19*MOD(B5;19)-7;30)*14%;)*7-6)+1

Funkce LAMBDA v listu

=LAMBDA(a;(KČ(("4/"&a)/7+MOD(19*MOD(a;19)-7;30)*14%;)*7-6)+1)(B7)

Funkce LAMBDA v s využitím Definovaného názvu

=Velikonoce(2022)

Tip: Pro vělikonoční pátek odečtete tři dny ;)

Čtvrtletí

Jak na výpočet čtvrtletí

Funkce napřímo - bez použití LAMBDA - na vyzkoušení, k výsledku se můžete dostat třemi způsoby

=ROUNDUP(MĚSÍC(B5)/3;0) =VYHLEDAT(MĚSÍC(B6);{1;4;7;10};{1;2;3;4}) =CELÁ.ČÁST((MĚSÍC(B7)-1)/3+1)

Funkce LAMBDA v listu opět třemi způsoby

=LAMBDA(datum;ROUNDUP(MĚSÍC(datum)/3;0))(B8) =LAMBDA(datum;VYHLEDAT(MĚSÍC(datum);{1;4;7;10};{1;2;3;4}))(B9) =LAMBDA(datum; CELÁ.ČÁST((MĚSÍC(datum)-1)/3+1))(B10)

Funkce LAMBDA v s využitím Definovaného názvu, kdy každý bude způsob bude mít svůj název:

=Ctvrtleti1(B11) =Ctvrtleti2(B12) =Ctvrtleti3(B13)

Bodové hodnocení

Na základě bodů, které josu celá čísla 0 - 100, potřebujete přiřadit písmeno (což může představovat známku, případně kvalitu dodavatele).

• 100 ... 91 A
• 90 ... 81 B
• 80 ... 71 C
• 70 ... 61 D
• 60 ... 0 E

Funkce napřímo - bez použití LAMBDA - na vyzkoušení

=KDYŽ(B5>90;"A";KDYŽ(B5>80;"B";KDYŽ(B5>70;"C";KDYŽ(B5>60;"D";"E"))))

Funkce LAMBDA v listu

=LAMBDA(b;KDYŽ(b>90;"A";KDYŽ(b>80;"B";KDYŽ(b>70;"C";KDYŽ(b>60;"D";"E")))))(B6)

Funkce LAMBDA v s využitím Definovaného názvu

=Znamka(B7)

Související články

Související články s funkci LAMBDA

• LET
• Syntaxe a použití funkce LAMBDA

Ke stažení

Soubor LAMBDA - výpočet plochy a obvodu obdelník ke stažení zdarma. Soubor využívá funkci LAMBDA - která je k dispozici v Office 365 - Insider.

Další soubor ke stažení zdarma jsou přípravě. Podpořit zveřejnění můžete podporou na Patreon.

Závěrem

Narazili jste na nějaké problémy, máte tip na vylepšení nebo doplnění článku, můžete se zmínit v komentářích.

Článek byl aktualizován: 01.10.2021 10:41

Pavel Lasák - autor webu

Microsoft Office (Word, Excel, Google tabulky, PowerPoint) se věnuji od roku 2000 (od 2004 na této doméně) - V roce 2017 jsem od Microsoft získal prestižní ocenění MVP (zatím jsem jediný z ČR v kategorií Excel). Své vědomosti a zkušenosti dávám k dispozici i on-line ve videích pro SEDUO. Ve firmách školím a konzultuji, učím na MUNI. Tento web již tvořím přes 15 let. Zdarma je zde přes 1.000 návodu, tipů a triků, včetně přes 250 různých šablon, sešitů.

           

Komentáře zatím nejsou

Můžete být prvními co zanechají smysluplný komentář.