Přeskočit navigaci | Přeskočit na novinky
     

Jste zde: Úvodní stránka » excel » funkce-matematicke » SOUCIN-SKALARNI-soucty-polozek-podminka-Excel
Microsoft Excel logo

SOUČIN.SKALÁRNÍ (SUMPRODUCT) - součty položek Excel

Videokurzy Excel

Ve spolupráci se SEDUO jsem vytvořil několik videokurzů:

Jak na součty položek v poli (matici, sloupci) odpovídající požadavku? Aneb podíváte se na zoubek naprosto unikátní funkci SOUČIN.SKALÁRNÍ, projdeme na praktických příkladech a naučíte se využít i náhrady této funkce (napřílad SUMIFS, COUTIFS), pokud vás tato funkce nezaujme (což doufám, že se nestane a budete z ní nadšeni ;)).

Úvodem do funkce SOUČIN.SKALÁRNÍ

Jak na součin (součet) položek v matici (tabulce) v Excel na základě podmínek, aneb praktické využití funkce SOUČIN.SKALÁRNÍ (v angličtině SUMPRODUCT), jednak její použití v listu, ruční výpočet až po využití funkce SOUČIN.SKALÁRNÍ ve VBA. Nezapomenu zmínit, funkce které funkci SOUČIN.SKALÁRNÍ dokáži nahradit.

Jak na funkci SOUČIN.SKALÁRNÍ prakticky od A do Z ukazuji v tomto článku, pro přehlednost je rozdělen na kapitoly:


Teorie použití SOUČIN.SKALÁRNÍ

Funkce SOUČIN.SKALÁRNÍ (v angličtině SUMPRODUCT) vrátí druhou odmocninu. Jak ji zapsat?

Syntaxe česky:

SOUČIN.SKALÁRNÍ(pole1;[pole2];[pole3];...) SOUČIN.SKALÁRNÍ(pole1*[pole2]*[pole2]3;...)

Syntaxe anglicky:

SUMPRODUCT(pole1,pole2,pole3,...)

Popis argumentů:

  • pole - Povinný argument. První argument ve formě tabulky (sloupce, matice), jejíž jednotlivé položky chcete násobit a poté sečíst.
  • pole - nepovinné argumenty - Jedná se o druhý až 255 argument ve formě tabulky (sloupce, matice), jejíž jednotlivé položky chcete násobit a poté sečíst.

Poznámky:

  • Oblasti tabulek, matic musí mít stejný rozměr.
  • .
  • Nečíselné typy jsou jako nuly
  • Někde v nápovědách je pole označeno jako matice (jde jen o jiný název).
Excel funkce SOUČIN.SKALÁRNÍ - argumenty

Základní použití funkce SOUČIN.SKALÁRNÍ

Příklad 1

Data pro Excel funkce SOUČIN.SKALÁRNÍ

Potřebuji zjistit celkové nálady, když mám tabulku se sloupci počet ks a cena (neboli vynásobit cena * kusy a pak všechny položky sečíst - lze udělat pomocným sloupem a využít funkce SUMA) - potřebuji-li jen toto číslo mohu využít funkci SOUČIN.SKALÁRNÍ a ušetřím pomocný sloupec.


=SOUČIN.SKALÁRNÍ(B6:B8;C6:C8)

Neboli funkce provede

3*10+2*5+1*1 30 + 10 + 1 = 41 Excel funkce SOUČIN.SKALÁRNÍ

Příklad 2

Data pro Excel funkce SOUČIN.SKALÁRNÍ

Potřebuji zjistit celkové nálady, když mám tabulku se sloupci počet ks a cena a počet prodejů (neboli vynásobit cena * kusy * počet prodejů a pak všechny položky sečíst) - potřebuji-li jen toto číslo tak opět využiji funkci SOUČIN.SKALÁRNÍ.


=SOUČIN.SKALÁRNÍ(B20:B22;C20:C22;D20:D22)

Neboli funkce provede

3*10*2 + 2*5*3 + 1*1*5 60 + 30 + 5 = 95 Excel funkce SOUČIN.SKALÁRNÍ

Ruční zápis matice do funkce SOUČIN.SKALÁRNÍ

Ukázka že SOUČIN.SKALÁRNÍ může pracovat i s maticemi.

=SOUČIN.SKALÁRNÍ({1\2;3\4;5\6})

nebo

=SOUČIN.SKALÁRNÍ({1;3;5};{2;4;6}) Excel funkce SOUČIN.SKALÁRNÍ

Poznámka

Zápis se může lišit podle verze Excelu, ale o maticích jsem psal více zde: Jak na matice v Excel. Takže zde jen pro dokreslení situace a souvislostí.

Podmínky pro funkci SOUČIN.SKALÁRNÍ

Data pro Excel funkce SOUČIN.SKALÁRNÍ

Funkci SOUČIN.SKALÁRNÍ využijeme jako podmínkovou, která nám bude sčítat (neboli náhrada funkce SUMIFS) nebo počítat počet (neboli náhrada funkce COUNTIF) na základě podmínek.

Budete mít tabulku, kde jsou ve třech sloupcích tato data Pracovník, Měsíc, a Počet. Jedná se o fiktivní data prodejů na prodejně. V dalších ukázkách se hodnoty ve zdrojové tabulce mohou lišit (v rámci procvičení zkuste vypočíst i jinak, využitím jiných funkcí a zkontrolovat, že vaše úvahy jsou správné / funkce počítá, tak jak potřebujete).

Součet

Začnete součtem, kdy položky v součtu musí odpovídat podmínkám:

  • Pracovník Pepa
  • Měsíc Leden
  • Pracovník Pepa a Měsíc Leden

Řešením:

=SOUČIN.SKALÁRNÍ((B6:B17="pepa")*D6:D17) =SOUČIN.SKALÁRNÍ((C6:C17="leden")*D6:D17) =SOUČIN.SKALÁRNÍ((B6:B17="pepa")*(C6:C17="leden")*D6:D17)

Poslední řešení pro Pepu a leden, lze provést i jinak, například:

=SOUČIN.SKALÁRNÍ(--(B6:B17="pepa");--(C6:C17="leden");D6:D17) =SOUČIN.SKALÁRNÍ(0+(B6:B17="pepa");0+(C6:C17="leden");D6:D17) =SOUČIN.SKALÁRNÍ(1*(B6:B17="pepa");1*(C6:C17="leden");D6:D17)

Tak co už se vám funkce SOUČIN.SKALÁRNÍ začíná líbit? Nahradit ji můžete SUMIFS:

=SUMIFS(D6:D17;B6:B17;"pepa";C6:C17;"leden")

Pozor: Jde o logické funkce, takže nelze mít jen středník, nevypočte:

=SOUČIN.SKALÁRNÍ((B6:B17="pepa");(C6:C17="leden");D6:D17)

O chybách ještě píšu v další kapitole.

Ukázka:

Excel funkce SOUČIN.SKALÁRNÍ ručně

Počet

Součet máte za sebou a podívejte se ještě jak na počet (řádků splňujících podmínku).

Z důvodů porovnání bude mít úkol stejné podmínky, jen nepůjde o součet ale o počet, podmínky zůstávají:

  • Pracovník Pepa
  • Měsíc Leden
  • Pracovník Pepa a Měsíc Leden

Řešením:

=SOUČIN.SKALÁRNÍ((B6:B17="pepa")*1) =SOUČIN.SKALÁRNÍ((C6:C17="leden")*1) =SOUČIN.SKALÁRNÍ((B6:B17="pepa")*(C6:C17="leden"))

Poslední řešení pro Pepu a leden, lze provést i jinak, například:

=SOUČIN.SKALÁRNÍ(--(B6:B17="pepa");--(C6:C17="leden")) =SOUČIN.SKALÁRNÍ(0+(B6:B17="pepa");0+(C6:C17="leden")) =SOUČIN.SKALÁRNÍ(1*(B6:B17="pepa");1*(C6:C17="leden"))

SOUČIN.SKALÁRNÍ lze nahradit funkce COUNTIF:

=COUNTIFS(B6:B17;"pepa";C6:C17;"leden")

Ukázka:

Excel funkce SOUČIN.SKALÁRNÍ ručně

Rozsah (více) podmínek SOUČIN.SKALÁRNÍ

Excel funkce SOUČIN.SKALÁRNÍ ručně

Mějte podobnou tabulku jako v předchozím případě. Kdy máte ale několik požadavku co potřebujete aby výpočet splňoval:

  • Musí jít o Ivu (Iva) a Pepu (Pepa).
  • Hodnoty v prodej větší než 2
  • Hodnoty v prodej větší než 11

Samozřejmě jako v předchozím potřebuji mít vypočten součet i počet.

Jako domací cvičení si můžete vyzkoušet využití funkcí SUMIFS a COUNTIFS.

Součet

Pro součet, kdy v jednom sloupci mám více nezávislých podmínek použijete + (plus) jelikož potřebujete sčítat řádky, která vyhovují podmínce Pepa nebo Iva (pro rozsah je * (krát) musí splňovat větší a zároveň menší):

=SOUČIN.SKALÁRNÍ((B6:B18="Pepa")+(B6:B18="Iva");(C6:C18>2)*(C6:C18<11);C6:C18)

nebo

=SOUČIN.SKALÁRNÍ((B6:B18="Pepa")+(B6:B18="Iva");--(C6:C18>2);--(C6:C18<11);C6:C18)

Počet

=SOUČIN.SKALÁRNÍ((B6:B18="Pepa")+(B6:B18="Iva");--(C6:C18>2);--(C6:C18<11))

Ukázka:

Excel funkce SOUČIN.SKALÁRNÍ ručně

Chyby SOUČIN.SKALÁRNÍ

Co zobrazí SOUČIN.SKALÁRNÍ u chybové hodnoty, textu místo čísla, nesprávné oblasti atd. Zatím rozebírám tyto chyby (časem doplním i další):

  • Logická
  • Nesourodá oblast
  • Hodnota místo čísla
  • Chybová hodnota v buňce

Logická

Je potřeba pochopit jak funkce funguje, doporučuji si projít příklady, kdy zjistíte a budete vědět bez dlouhého přemýšlení, v které situaci použijete +, kdy středník, atd.

Nesourodá oblast

Funkce nemá ráda pokud jsou oblasti nesourodé. Pokud se tak stane obdržíte chybu #HODNOTA!

=SOUČIN.SKALÁRNÍ(B7:B9;C7:C8)

Hodnota místo čísla

Jak jsem psal u syntaxe, pokud místo čísla budete mít text (pozor i číslo může být textem!) Tak se tato hodnota bere jako nula.

=SOUČIN.SKALÁRNÍ(B16:B18;C16:C18)

Chybová hodnota v buňce

Pokud pole (matice) obsahuje chybovou hodnotu, vrátí funkce také chybovou hodnotu:

=SOUČIN.SKALÁRNÍ(B25:B27;C25:C27) Excel funkce SOUČIN.SKALÁRNÍ porovnání

Použití s funkce SOUČIN.SKALÁRNÍ s využitím VBA

Jak využít funkce SOUČIN.SKALÁRNÍ ve VBA

Dim Pocet, Cena As Range Set Pocet = Range("B5:B7") Set Cena = Range("C5:C7") Hodnota = Application.SumProduct(Pocet, Cena) MsgBox (Hodnota)

Zápis funkce do buňky pomocí VBA:

Range("B9").Formula = "=SUMPRODUCT(B5:B7,C5:C7)" Range("B10").FormulaLocal = "=SOUČIN.SKALÁRNÍ(B5:B7;C5:C7)" Excel funkce SOUČIN.SKALÁRNÍ - VBA Excel

Související články s funkci SOUČIN.SKALÁRNÍ

Další články související s matematickými funkcemi:


Microsoft Excel VBA - stahuj logo

Ke stažení

Soubor v přípravě.


Závěrem

Využíváte nějaký trik s funkcí SOUČIN.SKALÁRNÍ, můžete zmínit v komentářích.

Článek byl aktualizován: 30.08.2017 16:36

Odměna

Ušetřil vám tento web čas, peníze? Pomohl vyřešit problém? Jste ochotni poskytnout symbolickou odměnu na další rozvoj? Vybrte si formu odměny, která vám vyhovuje.


Pavel Lasák - autor webu

Pavel Lasák

Microsoft Office (Word, Excel, PowerPoint) se věnuji od roku 2000 (od 2004 ne této doméně) - Roku 2017 jsem od Microsoft získal prestižní ocenění MVP (zatím jsem jediný z ČR v kategorií Excel). Své vědomosti a zkušenosti dávám k dispozici také na on-line videích pro SEDUO. Školím a konzultuji, učím na MUNI. Hlavně tvořím tento web. Je zde k dispozici přes 1.000 návodu, tipů a triků včetně stovek různých šablon, sešitů.

   Pavel Lasák LinkedIn Profil    Pavel Lasák Google+ Profil    Pavel Lasák facebook Profil    Pavel Lasák twitter Profil


Komentáře zatím nejsou

Můžete být prvními co zanechají smysluplný komentář.






Excel


Sdílejte

Pomohl Vám návod?
Sdílejte na Facebooku, G+
LinkedIn...

Nové články


Newsletter

Přihlaste se odběru novinek a získejte:
Ebook zdarma -
10 kroků ke zvládnutí (Word, Excel, PowerPoint)
Šipka Kniha 3D Více o ebooku ...

TOPlist Licence Creative Commons webarchiv rss XML

Stránky o MS Office (Excel) produktu společnosti Microsoft. Neslouží jako technická podpora.
| Email na autora: pavel.lasak@gmail.com | Copyright © : Pavel Lasák 2004 - 2017 | 487

Tento web zatím neprošel jazykovou korekturou. Beta verze redakčního systému.